Hi all,
Jerome Martin asked:
> I have a spool files on a 3000 and I need to print it using
> another hp. Of course, I have to keep all the control characters.
>
> How can I do this?
DenKor has 2 e3000s, each running a job that logs into the
other machine (we have the NS3000 product). It can probably
be changed to be more CI-efficient, but "if it ain't broke..."
This job calls two external files: an EDITOR 'EDTIN' file (SPOOLMOV.
USE), which creates a temporary command file that calls a permanent
command file (SPOOLMOV.XEQ) once for each file being moved.
!JOB SPOOLMOV,MGR.SPMOVE,SPOOL;HIPRI;OUTCLASS=LP,1,1
!
!###########################################################
!#
!# SPOOLMOV - MOVES SPOOL FILES FROM ONE SYSTEM TO ANOTHER
!#
!###########################################################
!
!# LOG INTO THE REMOTE SYSTEM
!
!DSLINE SYSB;OPEN
!REMOTE HELLO SPOOLMOV,MGR.SPMOVE,SPOOL;INPRI=13
!
!###########################################################
!
!# LOOP UNTIL 7PM
!
!WHILE HPHOUR < 22
!
! BUILD HOLDFILE;REC=-80,,F,ASCII;NOCCTL;TEMP
! FILE HOLDFILE,OLDTEMP
!
!# LIST SELECTED SPOOL FILES INTO TEMP FILE JUST CREATED
!
! SETVAR CIERROR,0
! LISTSPF O@; SELEQ= [ DEV=PRINTR AND PRI>2 AND &
! FORMID="" AND STATE="READY" ] > *HOLDFILE
!
! IF CIERROR = 0 THEN
!
!# IF FILES WERE FOUND, CREATE A TEMPORARY COMMAND
!# FILE (SPOOLMOV.SPOOL) TO MOVE THE FILES, THEN
!# EXECUTE AND PURGE IT - NOTE - CALLS SPOOLMOV.XEQ
!
! RESET HOLDFILE
! FILE EDITIN=SPOOLMOV.USE
! EDITOR
!
! XEQ SPOOLMOV.SPOOL
! PURGE SPOOLMOV.SPOOL
!
! ELSE
!
! RESET HOLDFILE
!
! ENDIF
!
! PURGE HOLDFILE,TEMP
!
! PAUSE 90
!
!ENDWHILE
!
!###########################################################
!
!REMOTE BYE
!DSLINE @;CLOSE
!
!SET STDLIST=DELETE
!
!EOJ
------------------------------------- spoolmov.use:
<< THIS FILE IS USED BY SPOOLMOV JOB >>
<< AS AN INPUT FILE FOR THE EDITOR >>
T HOLDFILE
DQ 1/3
FQ "INPUT SPOOL FILES"
DQ *-1/LAST
LQ FIRST
WHILE
FQ "CREATE"
DQ *
CQ 49/80 TO "" IN ALL
CQ 40 TO ",DEV=" IN ALL
CQ 34/36 TO ",COP=" IN ALL
CQ 30 TO ",PRI=" IN ALL
CQ 11/19 TO ",FILEDES=" IN ALL
CQ " " TO "" IN ALL
CQ "$" TO "" IN ALL
C 1/2 TO "SPOOLMOV.XEQ " IN ALL
KEEP SPOOLMOV.SPOOL
EXIT
------------------------------------- spoolmov.xeq:
PARM SPOOLID,PRI,COP,DEV,FILEDES
#
# THIS SCRIPT MOVES SPOOL FILES
#
SETVAR CIERROR,0
CONTINUE
DSCOPY O!SPOOLID.OUT.HPSPOOL;!FILEDES:SYSB;MOVE
IF CIERROR = 0 THEN
REMOTE SPOOLF !FILEDES; PRINT; DEV=!DEV; PRI=!PRI; COPIES=!COP
REMOTE PURGE !FILEDES
ENDIF
-------------------------------------
HTH!
+-------------------------------------------------------------------+
My mind is my own, as are my ideas and opinions.
My heart, body, and soul, however, all belong to others. Tim.
+-------------------------------------------------------------------+
Tim Ericson tericson DenKor Dental Management Corp.
Sr. Systems Analyst at denkor 503-526-4440 (my direct number)
(& Systems Manager) dot com http://www.denkor.com
Programming HPe3000s since 1983! Quality dental care since 1970!
+-------------------------------------------------------------------+
UDCs and Command Files: http://www.denkor.com/hp3000/command_files
+-------------------------------------------------------------------+
|
