Why close the door to the barn when your houses are already gone.
The answer is; have the job check it's own $STDLIST
Attached is an example of a job stream that makes use of planjane M.P.E.,
no additional software is required, POSIX environment is required but
that comes with M.P.E., right. You'll need to modify line #1 to logon
to your machine correctly, but that's it folks.
At the end on the job stream two Variables will exists.
Warnnbr = the number of QUIZ warnings found in the $stdlist.
Errsnbr = the number of QUIZ errors found in the $stdlist.
use your imagination, this could be a system level "EOJ" UDC.
_________________________________
Michael Anderson
Student Services Programmer/Analyst
Spring Independent School District, Houston, Texas, 77090
281.586.1105
!job test,mgr.vista,srcsisd
!showvar @
!#*************************************************
!Comment *W* The current $STDLIST's DFID is:
!Comment *W* !HPSPOOLID.OUT.HPSPOOL
!
!Comment Note the *W* above, now here's an *E*
!#
!Comment Now I'll check for check for both, or actually
!Comment you could use any string.
!
!#-----------*
!# Setup a place holder file to hold the ASCII digits
!# that will represent the number of Quiz Warnnings or
!# Errors. I'll make this a temporary file called plachold.
!#-----------*
!purge plachold,temp
!file x=plachold,oldtemp
!build plachold;rec=-80,1,f,ascii;temp
!
!#-----------*
!# Setup a temporary $STDLIST file, the stdlist will
!# be temporaryily copied to this file.
!#
!#-----------*
!purge tempfile,temp
!file y=tempfile,oldtemp
!build tempfile;rec=-256,1,f,ascii;disc=100000;temp
!
!#-----------*
!# Now actually copy the $STDLIST.
!# Using the PRINT command and the HPSPOOLID variable.
!#
!#-----------*
!Setvar MYstdlist '!HPSPOOLID' + '.OUT.HPSPOOL'
!print !MYstdlist;page=0 > *y
!
!#-----------*
!# Next check our temporary stdlist file for any string
!# you want to use. This example is for Quiz Warnnings,
!# so the string is *W* NOTE: -ic = caseless search, count only.
!#-----------*
!fgrep.hpbin.sys "-ic *w*" < *y > *x
!input WarnCount < *x
!Setvar Warnnbr !WarnCount
!if Warnnbr <> 0 Then
! Echo !Warnnbr Warnnings occured
!endif
!
!
!#-----------*
!# And Quiz Errors also.
!#-----------*
!fgrep.hpbin.sys "-ic *e*" < *y > *x
!input ErrsCount < *x
!Setvar Errsnbr !ErrsCount
!if Errsnbr <> 0 Then
! Echo !Errsnbr Errors occured
!endif
!showvar @
!eoj
|