JeffH wrote:
> Does anyone know if you can limit the number of sessions a specific user
can
> have?
>
> Most of our users are accessing the HP across ethernet connection. By
> running Minisoft 32 multiple times the users have found they can logon to
> the hp several times. I have one that consistantly logs on 5 times all day
> long. Welp, as you could guess, they are using up our user license space.
> What I would like to do is limit some to 1 sesion and others to 2
sessions.
> Can this be accomplished?
>
> TIA
> Jeff
You can limit them to 1 session easily, without Temp files and 3rd party
programs, and this works for us.
We have a system udc which does a TELL to the person logging on, and
depending
on the error message received, allows them on, or sends them to a Multi
Logon
Verification and Authorization command file.
This file locks their PC screen until they enter a "release" code form
Operations, or type BYE to sign off. If this is not a ligitimate logon. the
real person logged on gets a message.
We allow some individuals and some entire accounts such as SYS,
PROG(ramming),
etc to log on multiple times by putting a file in a group called MLOGON with
their logon name or account name as the filename. This requires unique
logon
names, but so does our security.
The code is as follows. If it is not understandable, contact me.
:print sysudc.udc.sys
STARTMENU
OPTION LOGON,NOBREAK,NOLIST,NOHELP
SETVAR ESC CHR(27)
SETVAR BELL CHR(7)
SETVAR ENH "!ESC"+"&d"
SETVAR HPAUTOCONT TRUE
IF HPINTERACTIVE THEN
IF NOT FINFO('!["!HPUSER"+".MLOGON.COM"]','EXISTS') THEN
IF NOT FINFO('!["!HPACCOUNT"+".MLOGON.COM"]','EXISTS') THEN
SETVAR HPMSGFENCE 1
ERRCLEAR
TELL !HPUSER.!HPACCOUNT; MULTI LOGON ON !HPLDEVIN
IF CIERROR<>1619 AND CIERROR<>1620 THEN
SETVAR HPMSGFENCE 0
XEQ MLOGON.CMD.COM
IF "!SCMULTI"<>"YES" THEN
BYE
ENDIF
ENDIF
SETVAR HPMSGFENCE 0
ENDIF
ENDIF
ENDIF
******************************************
:print mlogon.cmd.com
OPTION nobreak,nohelp,nolist
ECHO ![ESC]H![ESC]J
ECHO *****************************************************
ECHO *****************************************************
ECHO ** **
ECHO ** **
ECHO ** Y O U A R E A L R E A D Y **
ECHO ** L O G G E D O N O N C E . **
ECHO ** **
ECHO ** **
ECHO ** CONTACT OPERATIONS FOR A MULTI ACCESS CODE OR **
ECHO ** TYPE BYE TO RELEASE THE TERMINAL. **
ECHO ** **
ECHO ** PHONE: KEITH Extn 653 **
ECHO ** KATHY - Extn 237 **
ECHO ** TONY - Extn 235 **
ECHO *****************************************************
ECHO *****************************************************
ECHO
ECHO
SETVAR SCMULTI "YES"
SETVAR SCCODE 0
CONTINUE
SETVAR HPMSGFENCE 2
CONTINUE
WHILE "!SCCODE"<>"![!HPMONTH*!HPHOUR*(!HPMINUTE/2+1)*!HPDAY*!HPDATE*69]"
CONTINUE
INPUT SCCODE;PROMPT="INPUT CODE FROM OPERATIONS OR BYE?";WAIT=90
CONTINUE
IF "!SCCODE"="BYE" OR "!SCCODE"="0" THEN
CONTINUE
SETVAR SCMULTI "NO"
CONTINUE
SETVAR SCCODE "![!HPMONTH*!HPHOUR*(!HPMINUTE/2+1)*!HPDAY*!HPDATE*69]"
ENDIF
ENDWHILE
SETVAR HPMSGFENCE 0
If we give them a "release" code, they can logon as many times as we allow
them
to. The code for us to generate the release code is:
USER DEFINED COMMAND FILE: RELCODE.CMD
ECHO THE RELEASE CODE FOR FREEING A TERMINAL IS:
ECHO ![!HPMONTH*!HPHOUR*(!HPMINUTE/2+1)*!HPDAY*!HPDATE*69]
ECHO ------------
If you need to allow them exactly 2, then you will have to use one of the
"user
list to a file" suggestions.
Tony Peters
_/_/_/_/_/ _/_/_/_/_/ Project Manager - New Technology
_/ _/ _/ _/ S&C Electric Canada Ltd
_/ _/ _/ 90 Belfield Rd
_/_/_/_/_/ _/_/_/ _/ Toronto ON M9W 1G4
_/ _/ _/ Ph 416 249-9171
_/ _/ _/ _/ Fax 416 249-3193
_/_/_/_/_/ _/_/_/_/_/ Email [log in to unmask]
My Thoughts, My Fault. Don't blame anyone else, cause they have no idea
what I am thinking. Good thing too.
|