Subject: | |
From: | |
Reply To: | |
Date: | Wed, 7 May 1997 15:34:23 PST8 |
Content-Type: | text/plain |
Parts/Attachments: |
|
|
>Author: [log in to unmask] at CCGATE
>Date: 05/05/97 09:44 AM
>I would also like to see if this could be done "Neatly". I have a
>similar problem, and have been using the following work-around:
>
>My back-up normally takes two hours. When I stream the back-up job, I
>also stream a job (scheduled to start in 2-1/2 hours) that does an
>ABORTJOB on the back-up. It's a little dangerous, but our SOP is to
>abort the back-up anyway (If it's hung-up), so users can get on the
>system ASAP.
<snip>
The following maybe a little neater:
1. Within your backup job insert the following commands
!purge Bkupfile.data >$null
!build Bkupfile.data;rec=-72,,f,ascii
!file BK=Bkupfile.data,old
!echo setvar backup_jobnum "#!hpjobtype!hpjobnum" > *BK
!stream jmonitor.job...
!pause 5
The above will write the job number of the backup into a file in a
form that can be executed by the 'monitor' job and placed in a CI
variable. It then streams the monitor job and waits a few seconds to
allow the monitor job to begin execution.
2. The monitor job should be as follows: (Note that it must have HIPRI)
!job jmonitor,manager.sys;HIPRI;outclass=,1;pri=cs
!comment
!comment This job is of use ONLY when submitted by the backups.
!comment It will monitor the executing backup job and determine
!comment if there are any pending replies. (Under normal cases
!comment a pending reply would mean that another tape is needed
!comment in order for the backup to complete).
!comment
!comment 'Receive' the 'passed' info from the backup job
!comment
!xeq Bkupfile.data
!Purge Bkupfile.data
!showvar backup@
!
!comment
!comment Set some environment variables
!comment
!setvar Loop_Delay 900
!setvar Loop 0
!setvar not_accepting 1627
!setvar Backup_running true
!comment
!comment
!while Backup_running do
! showtime
! continue
! purge *rc >$null
! build rcfile;rec=-100,,f,ascii;msg;temp
! file rc=rcfile,oldtemp
! tell !backup_jobnum Hi there
! setvar Backup_running cierror = not_accepting
! if Backup_running then
! pause !Loop_delay
! setvar Loop Loop + 1
! echo *** LOOP # !Loop ***
! recall > *rc
! echo *** Recall Dummy Record *** >> *rc
! setvar Loop2 0
! setvar recall_eof finfo("*rc",'eof') - 1
! setvar Reply_Pending 0
! while Loop2 < recall_eof
! setvar Loop2 Loop2 + 1
! input Rc_Text;wait=2 < *rc
! echo !Rc_Text
! if pos("!backup_jobnum/", Rc_Text) <> 0 then
! purge *rc >$null
! breakjob !backup_jobnum
! continue
! abortjob !backup_jobnum
! endif
! endwhile
! endif
!endwhile
!eoj
The loop_delay can be adjusted to suit your environment.
Good luck
Regards
Paul H. Christidis
310)513-5808
|
|
|