Randy

You must do these things to get the LJ5Si to go to stacker mode:-

Send an escape sequence to the Printer.
Switch it off and on again.
Choose output bin 2 on the control panel.

Here is my little command file. HCO (High Capacity Output - I know, I
know)
It sends the right escape sequences.
It also prints instructions onto the printer for the next two steps :)

Regards

Neil


USER DEFINED COMMAND FILE:  HCO.CMD.SYS

parm ldev="" mode="NONE"
if ups("!mode") <> "STACKER" &
   and ups("!mode") <> "MAILBOX" &
       and ups("!mode") <> "SEPARATOR" then
   echo Usage HCO printer-ldev mode
   echo
   echo    where printer=ldev is ldev e.g. 814
   echo      and mode is one of:-
   echo
   echo         STACKER
   echo         MAILBOX
   echo         SEPARATOR
   echo
   echo   Will set the printer to the correct mode
   escape
endif
if "!ldev" = "" then
   echo You must give the target printer's ldev number
   escape
endif
file hcolp;dev=!ldev,13
setvar esc CHR(27)
setvar escE CHR(27) + "E"
echo !escE > hcof
echo !esc&l2G >> hcof
echo !esc(s1p14v1s0b4168T >> hcof
if ups("!mode") = "STACKER" then
  echo !esc&l2I >> hcof
endif
if ups("!mode") = "MAILBOX" then
  echo !esc&l2K >> hcof
endif
if ups("!mode") = "SEPARATOR" then
  echo !esc&l2J >> hcof
endif
echo Now switch the printer off, and on again >> hcof
echo                                          >> hcof
echo Then at the front panel:-                >> hcof
echo   Push              Until                >> hcof
echo                                          >> hcof
echo    Menus             Configuration Menu  >> hcof
echo    Items             Paper Destination=  >> hcof
echo    +                 Optional Output Bin 2 >> hcof
echo    Select*           (Asterisk appears)    >> hcof
echo                                            >> hcof
echo Now do a self test to check.               >> hcof
print hcof;out=*hcolp
/