We do exactly that. We have a group, JOB.SYS with security access
L,X:any so that MANAGER.SYS passwords are not available to the public.
In this group is a nightly job, BULDACCT that creates output files for
each volume set. Here is the segment for the STAR volume set. As you
are probably aware, BULDACCT on its own creates two volatile files,
BULDJOB1 and BULDJOB2 with embedded MANAGER.SYS passwords. My job ends
up with the same two jobs in JOB.SYS with new names.
:TELLOP !HPJOBNAME IS STARTING STAR
:TELL @,MANAGER.SYS !HPJOBNAME IS STARTING STAR
:IF BOUND (BULDJOB) THEN
: DELETEVAR BULDJOB
:ENDIF
:IF FINFO ("STAR1.JOB","EXISTS") THEN
: PURGE STAR1.JOB
:ENDIF
:IF FINFO ("STAR2.JOB","EXISTS") THEN
: PURGE STAR2.JOB
:ENDIF
:RUN BULDACCT.PUB.SYS;INFO=&
: "DISC,FTPSERVE,LOCKBOX,OCSLIB,&
: SMALLSYS,STAR&
: %VSACCT=STAR"
:RUN EDITOR.PUB.SYS
TEXT BULDJOB1,UNN
CHANGE ",2",",2;SPSAVE",FIRST
CHANGE "BULDJOB","STAR",FIRST/FIRST+1
KEEP
TEXT BULDJOB2,UNN
CHANGE ",2",",2;SPSAVE",FIRST
CHANGE "BULDJOB","STAR",FIRST/FIRST+1
KEEP
EXIT
:SETVAR BULDJOB 0
:IF FINFO ("STAR1.JOB.SYS","EXISTS") THEN
: ALTSEC BULDJOB1;ACCESS=(R,W,A,L,X,:CR)
: SETVAR BULDJOB BULDJOB + 1
:ELSE
: RENAME BULDJOB1,STAR1.JOB
:ENDIF
:IF FINFO ("STAR2.JOB.SYS","EXISTS") THEN
: ALTSEC BULDJOB2;ACCESS=(R,W,A,L,X,:CR)
: SETVAR BULDJOB BULDJOB + 1
:ELSE
: RENAME BULDJOB2,STAR2.JOB
:ENDIF
:IF BULDJOB > 0 THEN
: TELL @,MANAGER.SYS !HPJOBNAME HAD CLASH ON 'STAR'
: TELLOP !HPJOBNAME HAD CLASH ON 'STAR'
: TELL @,MANAGER.SYS !HPJOBNAME WILL NOW ABORT
: TELLOP !HPJOBNAME WILL NOW ABORT
: ESCAPE
:ENDIF
:TELLOP !HPJOBNAME HAS FINISHED STAR
:TELL @,MANAGER.SYS !HPJOBNAME HAS FINISHED STAR
Leonard Berkowitz
RIA Group (Warren, Gorham & Lamont)
617-292-8349
______________________________ Reply Separator _________________________________
Subject: BULDACCT job
Author: Mike Kapsak <[log in to unmask]> at Internet-Exchange
Date: 11/18/96 10:19 AM
I would like some assistance using the BULDACCT program on
multiple volume sets. I have three volume sets on one 967,
MPEXL_SYSTEM_VOLUME_SET
TESTVOL
PRODDB,
and want to know if I can run one BULDACCT job to put the account
structure from all three sets into one jobstream. I will be running this
progam daily to retain an up to date account structure in the unlikely
event of a disaster.
Any help is appreciated,
Mike Kapsak
|