<<I have been considering using the SYSGEN tape facility to provide a
complete backup for HP3000 operating system and user files but the store
parameter only allows the specification of a fileset. There is no option
for DIRECTORY which is essential for the securing of the directory
structure. Without this option it does not appear possible to have a
single tape set with the operating system, directory structure and files
completely captured for total recovery.
 
Is there a simple solution to achieving a SYSGEN tape set for complete
backup?>>
 
Put the DIRECTORY option in the indirect file. Here's what we use:
 
A script called MAKESLT -
 
USER DEFINED COMMAND FILE:  MAKESLT.SYSTEM.SCRIPTS
 
PARM STORETYPE="",MODE=""
comment****************************************************
comment
comment This command script starts a stream job to
comment create a new SLT tape and provide the sysgen
comment report listings.
comment
comment****************************************************
SETVAR SLT_STORETYPE "!STORETYPE"
IF "!SLT_STORETYPE" = "" THEN
  NSCONTROL STATUS
  ECHO NS users will be aborted in 15 seconds.  Press [Break]
  ECHO to terminate script and continue NS operations.
  PAUSE 15
  SETVAR SLT_AUTOCONT HPAUTOCONT
  SETVAR HPAUTOCONT TRUE
  STOPNS
  SETVAR HPAUTOCONT SLT_AUTOCONT
  DELETEVAR SLT_AUTOCONT
  STREAM JBSLT.STREAMS.SCRIPTS
ELSEIF UPS("!SLT_STORETYPE") = "SYS" THEN
  NSCONTROL STATUS
  ECHO NS users will be aborted in 15 seconds.  Press [Break]
  ECHO to terminate script and continue NS operations.
  PAUSE 15
  SETVAR SLT_AUTOCONT HPAUTOCONT
  SETVAR HPAUTOCONT TRUE
  STOPNS
  SETVAR HPAUTOCONT SLT_AUTOCONT
  DELETEVAR SLT_AUTOCONT
  STREAM JBSLTSYS.STREAMS.SCRIPTS
ELSEIF UPS("!SLT_STORETYPE") = "FULL" THEN
  NSCONTROL STATUS
  ECHO NS users will be aborted in 15 seconds.  Press [Break]
  ECHO to terminate script and continue NS operations.
  PAUSE 15
  SETVAR SLT_AUTOCONT HPAUTOCONT
  SETVAR HPAUTOCONT TRUE
  STOPNS
  SETVAR HPAUTOCONT SLT_AUTOCONT
  DELETEVAR SLT_AUTOCONT
  STREAM JBSLTFUL.STREAMS.SCRIPTS
ELSE
  ECHO Syntax:
  ECHO   MAKESLT [store]
  ECHO     where [store] is files to add to store on SLT -
  ECHO       blank - no STORE added
  ECHO       SYS   - System account files
  ECHO       FULL  - Full system (except databases)
ENDIF
DELETEVAR SLT_STORETYPE
 
which, when called with "FULL" as the parameter, streams the following
job -
 
!job sltfull,manager.sys
!comment****************************************************
!comment
!comment This stream job creates a System Load Tape (SLT)
!comment with a STORE of all system files (except databases
!comment and the BACKUP account).
!comment
!comment****************************************************
!comment****************************************************
!comment  Setup File Equations
!comment****************************************************
!file sysgtape    ;dev=8
!comment ***************************************************
!comment   Build file with date of this SLT
!comment ***************************************************
!continue
!purge sltdate
!echo SLT created on !hpdatef at !hptimef > sltdate
!save sltdate
!tellop;**********************************************
!tellop;       Creating System Load Tape
!tellop;**********************************************
!sysgen
TAPE MODE=VERBOSE STORE=!FULLSYSL
exit
!tellop;**********************************************
!tellop;               Job MKSLTJOB Complete
!tellop;**********************************************
!SET STDLIST=DELETE
!eoj
 
which stores files as specified in FULLSYSL -
 
/ - /BACKUP/ - <redundant databases here>;DIRECTORY;SHOW
 
So we end up with an SLT/STORE tape containing everything on the system,
including the directory (except the BACKUP account, which is on a private
volume set and is backed up nightly on the other tape drive).
 
Steve Dirickson         WestWin Consulting
(360) 598-6111  [log in to unmask]