Excellent suggestion Craig.

Added the BULDACCT prior to the backup and had it log in as MANAGER.SYS 
instead of OPERATOR.SYS.  I tried running the BULDACCT comment as 
OPERATOR and received the following error message:

:buldacct

BUILD ACCOUNT PROGRAM FOR DIRECTORY MIGRATION. Version A.50.25

**************************************
*** PASCAL error detected during    **
*** execution.  Pascal run-time     **
*** library error no.      706**
***                                 **
*** Error occurred while processing **
*** the following command:          **
***                                 **
*** Last record processed:          **
*** procedure no.          101**
*** userscap              **
**************************************
FILE NOT OPENED (PASCERR 706)
FILE NOT OPENED (PASCERR 706)
 
ABORT: BULDACCT.PUB.SYS 
NM SYS   a.00aa1288 dbg_abort_trace+$24
NM PUB   2a0.000b7a34 P__PASCFERROR+$3e0
NM PROG  464.0002f4bc _start+$55c4
Program terminated in an error state. (CIERR 976)
:

Here is my modified backup job stream which works:

!JOB 
DUMP,MANAGER.SYS;OUTCLASS=300;PRI=CS;INPRI=2;spsave                     
!COMMENT
!COMMENT MODIFIED: 02-01-96  MJB
!COMMENT  PURPOSE: CHANGE INPRI FROM 1 TO 2 AND ADD LIMIT 0,50
!COMMENT
!COMMENT MODIFIED: 03-04-96  MJB
!COMMENT  PURPOSE: CHANGE BACK TO BACK.PUB.SCOP
!COMMENT
!COMMENT MODIFIED: 7-31-96 BY STB
!COMMENT  PURPOSE: REMOVE LIMIT SETTING 0,50
!COMMENT
!comment Modified by Dave Vogt  10/5/98
!comment changed to do a full backup nightly with a directory option.
!comment Why?  Because we have time!!!
!comment
!comment Modified by Dave Vogt 11/3/98
!comment Run TAPECTRL.PUB.ORBIT and did SHOWDEV 7.  Tape kept hanging
!comment after the LOADTAPE program was run for no appearent reason.
!comment Will try the TAPECTRL program to see if this solves it.
!comment
!comment Modified by Dave Vogt 11/20/98
!comment Changed the outclass from LP,1 to LP99.  The stdlist was not
!comment being purged on a nightly basis.
!comment Modified by Dave Vogt 3/22/99
!comment Added a LISTSPF o@;detail before the backup.  Will allow
!comment us to track lost spoolfiles easier.
!comment
!comment Changed by Dave 5/6/04
!comment Send the spoolfile listing and fulllst to ldev 300 to save
!comment so I can find information on files being stored.
!comment 
***********************************************************
******
!COMMENT  BZ  8/15/05  added stop and start of Conman so CCC account will
!COMMENT     be backed up
!comment Dave 8/16/05 add stop of Sleeper at beginning of backup
!comment then restream of sleeper and restart of Vsoft for same reason
!comment above.
!comment Dave 01/03/10
!comment Added BULDACCT prior to the backup.  This will create 2
!comment files BULDJOB1 and BULDJOB2 .pub.sys.  In the event of a
!comment disc drive failure, you can restore these files and stream them
!comment to rebuild the directory structures (BULDJOB1) and rebuild the
!comment users and UDC's (BULDJOB2).  This takes care to the problem of
!comment not having the directory information on the backup tape.
!comment Also had the job logon as MANAGER.SYS.  OPERATOR.SYS does not
!comment have the capability to perform this.
!comment 
***********************************************************
***
!
!ALLOWME.PUB.ORBIT
!FILE SPOOLLST;DEV=300,12;SPSAVE
!LISTF @.LOGGING.SYS,2
!LISTF [log in to unmask],2
!LISTSPF O@;DETAIL >*SPOOLLST
!
!LIMIT 0
!RUN CONMAN.SPOOL.CCC;INFO="STOP"
!PAUSE 45
!SETVAR STOPPED "NO"
!MPEX
WHILE STOPPED = "NO"
IF JSCOUNT('SPOOLMAN,SPOOL.CCC') = 0 THEN
SETVAR STOPPED "YES"
ELSE
PAUSE 30
ENDIF
ENDWHILE
EXIT
!
!comment Added abort of sleeper to make sure we get sleeper stuff
!comment backed by.  We will restart sleeper at the end of the
!comment dump ... Dave 8/16/05
!CONTINUE
!ABORTJOB SLEEPER,SLEEPER.SYS
!PAUSE 30
!
!SHOWTIME
!SHOWJOB
!
!BULDACCT

!
!FILE SYSLIST=FULLLST;DEV=300,12;SPSAVE
!RUN BACKUPPL.PUB.ORBIT
PURGE FULL.BACKUP.SYS
STORE !FULLFULL.BACKUP.ORBIT;FULL.BACKUP.SYS;COMPRESS=3;&
       AUTOREPLY=7;&
       DBSTORE;&
       SETDATE;&
       SHOW=LONG,DATES;&
       MAXRETRIES=100;&
       MAXERRORS = 10;&
       PROGRESS=10;&
       NOLOCK;DIRECTORY
 EXIT
!LISTF [log in to unmask],2
!SWITCHLOG
!SWITCHNMLOG
!SHOWJOB
!SHOWOUT
!RUN CONMAN.SPOOL.CCC;INFO="START"
!PAUSE 30
!SETVAR STARTED "NO"
!MPEX
WHILE STARTED = "NO"
IF JSCOUNT('SPOOLMAN,SPOOL.CCC') = 0 THEN
PAUSE 15
ELSE
SETVAR STARTED "YES"
ENDIF
ENDWHILE
EXIT
!DELETEVAR STOPPED
!DELETEVAR STARTED
!
!STREAM SLEEPERJ.SLEEPSTG.SYS
!PAUSE 30
!
!comment Restart of BACKG added to end of DUMP by Dave 8/16/05
!comment Vesoft files were not getting backed up because they were
!comment being accessed.
!RUN MAIN.PUB.VESOFT;PARM=1;INFO="BACKG STARTJOB"
!LIMIT 6,0
!PAUSE 30
!SHOWJOB
!comment end of BACKG comments.
!comment
!EOJ
/

* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *