We use a little script SENDFILE.XECMD.SYS to produce Sendmail/iX eMails
with attachments.
Some changes will be needed for LOC and XREPLYTO but also for the group
XECMD.SYS - I assume you do not have such a localized group!
The script bases on an older discussion in the Newsgroup and our changes.
I also wrote an article in the 3000Newswire some time ago ... named Freedom
to Mail from Your 3000, for Free which is still available under
http://www.hillschmidt.de/gbr/articles.htm
Here you can also find some other commandfiles.
Have a good day, Andreas
PARM SUBJECT="" TO="" MSGTEXT="" FILENAME="" REMOTEFILENAME="" REPLYTO="" &
ENTRY="MAIN"
COMMENT This command file will send an email with one or more attachments,
COMMENT including a message text
COMMENT REMARK: to send mutiple attachments, you must leave the parameter
COMMENT 'FILENAME' empty. As a result, you will prompted to enter
COMMENT filenames
IF UPS("!ENTRY") = "MAIN"
COMMENT
COMMENT CMD ENTRY: -- MAIN --
COMMENT
IF "!HPSYSNAME" = "ALPHA" OR "!HPSYSNAME" = "BETA" THEN
SETVAR LOC "SDOM1"
ELSE
SETVAR LOC "SDOM2"
ENDIF
SETVAR XSUBJECT "!SUBJECT"
SETVAR XTO "!TO"
SETVAR XMSGTEXT "!MSGTEXT"
SETVAR XFILENAME "!FILENAME"
SETVAR XRFN "!REMOTEFILENAME"
IF ( XRFN = "" ) THEN
SETVAR XRFN "!XFILENAME"
ENDIF
SETVAR XREPLYTO "!REPLYTO"
IF "!REPLYTO" = "" THEN
SETVAR XREPLYTO "!HPUSER.!HPACCOUNT"+"@"+"!HPSYSNAME.!LOC.DOM.COM"
ENDIF
IF ( XTO = "?" OR XTO = "" OR XSUBJECT = "" ) THEN
ECHO sendfile.xecmd.sys
ECHO
ECHO sendfile subject to msgtext filename [remotefilename] [replyto]
ECHO
ECHO subject: subject of the email message, must be quoted
ECHO to: user@domain
ECHO msgtext: mpe or posix filename, contains the message
text
ECHO filename: any mpe or posix filename
ECHO remotefilename: name of the file you want to call the
attachment
ECHO replyto: reply address, recommended
ECHO entry: value MAIN or ATTACH, only internally used
ECHO
ESCAPE
ENDIF
IF "!XMSGTEXT" <> ""
IF NOT FINFO("!XMSGTEXT","EXISTS")
ECHO sendfile.xecmd.sys: !XMSGTEXT not found
ESCAPE
ENDIF
ENDIF
IF "!XFILENAME" <> ""
IF (NOT FINFO("!XFILENAME","EXISTS")) THEN
ECHO sendfile.xecmd.sys: !XFILENAME not found
ESCAPE
ENDIF
ENDIF
SETVAR XFROM "!HPUSER.!HPACCOUNT"
FILE CM;DISC=1000000
COMMENT Generate a MIME boundary string.
SETVAR MAILSPF_SEP rht(rpt('-',36)+"!HPSUSAN!HPPIN!HPCPUMSECS",36)
COMMENT
COMMENT Generate all of the message headers.
COMMENT
ECHO From: "!XFROM" > *CM
ECHO To: !XTO >> *CM
ECHO Reply-To: !XREPLYTO >> *CM
ECHO Subject: !XSUBJECT >> *CM
ECHO MIME-Version: 1.0 >> *CM
ECHO Content-Description: "MIME Base64 encode" >> *CM
ECHO Content-Type: multipart/mixed; boundary="!MAILSPF_SEP">> *CM
ECHO >> *CM
COMMENT
COMMENT Generate the preamble (not normally displayed by MIME mail
clients).
COMMENT
ECHO This is a multi-part message in MIME format. >> *CM
COMMENT
COMMENT Generate the first body which contains the message output.
COMMENT
IF "!XMSGTEXT" <> ""
ECHO --!MAILSPF_SEP>> *CM
ECHO Content-Type: text/plain; charset=us-ascii >>*CM
ECHO Content-Transfer-Encoding: 7bit >>*CM
ECHO >> *CM
PRINT !XMSGTEXT >> *CM
ENDIF
IF "!XFILENAME" <> ""
XEQ !HPFILE ENTRY=ATTACH
ELSE
COMMENT
COMMENT to prompt for more than one attachment
COMMENT ANSWER has parameters --FILENAME,REMOTEFILENAME--
COMMENT
ECHO
ECHO INFO: Attachment parameters: FILENAME,REMOTEFILENAME
ECHO
SETVAR ANSWER "X"
WHILE ANSWER = "X"
SETVAR ANSWER ""
INPUT NAME=ANSWER;PROMPT="Attach file: "
SETVAR ANSWER LTRIM(ANSWER)
IF "!ANSWER" <> ""
SETVAR SSPOS POS(",",ANSWER)
SETVAR SSLEN LEN(ANSWER)
IF SSPOS = 0
SETVAR XFILENAME "!ANSWER"
SETVAR XRFN "!ANSWER"
ELSE
SETVAR XFILENAME LFT(ANSWER,SSPOS-1)
SETVAR XRFN RHT(ANSWER,SSLEN-SSPOS)
ENDIF
IF (NOT FINFO("!XFILENAME","EXISTS")) THEN
ECHO sendfile.xecmd.sys: !XFILENAME not found
ELSE
XEQ !HPFILE ENTRY=ATTACH
ENDIF
SETVAR ANSWER "X"
ENDIF
ENDWHILE
ENDIF
ECHO --!MAILSPF_SEP-->> *CM
COMMENT
COMMENT Mail the message.
COMMENT
XEQ SENDMAIL.PUB.SENDMAIL "-t" < *CM
ECHO Done.
ELSEIF UPS("!ENTRY") = "ATTACH"
COMMENT
COMMENT CMD ENTRY: -- ATTACH --
COMMENT
COMMENT
COMMENT Insert attachment as plain text.
COMMENT
ECHO --!MAILSPF_SEP>> *CM
ECHO Content-Type: text/plain; charset=us-ascii; name="!XRFN" >> *CM
ECHO Content-Transfer-Encoding: 8bit >> *CM
ECHO Content-Disposition: attachment; filename="!XRFN" >> *CM
ECHO >> *CM
PRINT !XFILENAME >> *CM
ENDIF
Best regards,
Andreas Schmidt
CSC Managed Services GmbH
Global Infrastructure Services, Global Processing Engineering Services
DuPont-Strasse 1, Room 1-346
D-61352 Bad Homburg
Germany
Phone: +49 (0) 6172 / 87-2117 Fax -2195 DUCOM x951-2117
eMail: [log in to unmask]
HP e3000 Intranet Information at http://web1.cscbhg.dupont.com/web/hp3000/
Unix Intranet Information at http://bhghpx12.bhg.dupont.com/
----------------------------------------------------------------------------------------
This is a PRIVATE message. If you are not the intended recipient, please
delete without copying and kindly advise us by e-mail of the mistake in
delivery. NOTE: Regardless of content, this e-mail shall not operate to
bind CSC to any order or other contract unless pursuant to explicit written
agreement or government initiative expressly permitting the use of e-mail
for such purpose.
----------------------------------------------------------------------------------------
"Dana Smith,
PMP" <dana_smith To: [log in to unmask]
@COMCAST.NET> cc:
Sent by: HP-3000 Subject: [HP3000-L] Sendmail with attachments...
Systems
Discussion
<HP3000-L
08/18/2004 08:45
PM
Please respond
to "Dana Smith,
PMP"
We're configuring our 3K with sendmail and notice the mailx client does not
allow for the sending of attachments. Is there another prevalent client out
there that is typically used when sending attachments or is PERL the
typical
solution?
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|