-----Original Message-----
From: Craig Lalley [mailto:[log in to unmask]]
Subject: [HP3000-L] CI Script question
First off let me say, this sight does not have MPEX.
How can I list all the file with more than 100 extents?
*********************************
I was bord today so I created a command file that will display what you are
looking for. It takes two parms, the first is the file set and the second is
the minimum # of extents to check for. It also shows EOF and sectors in the
output.
*****************************************************************
parm files,min_ext
# Joshua Johnson 02/03/2004
# Command lists file that have more than min_ext number of extents.
file tempf,oldtemp
if finfo('*tempf','exists')
purge tempf,temp
endif
build tempf;disc=50000;temp;msg
errclear
continue
listf !files,6 > *tempf
if cierror<>0
echo !hpcierrmsg
escape !cierror
endif
setvar _eof finfo('*tempf','eof')
setvar _c 0
setvar _c2 0
setvar _rec ''
setvar _not_found true
while _c<_eof
input _rec,<*tempf
setvar _rec rtrim(_rec)
if word(_rec,'.',3)<>'HPSPOOL' and finfo(_rec,'extents')>=!min_ext
if _not_found
echo FILE GROUP ACCOUNT EXTENTS EOF SECTORS
setvar _not_found false
endif
setvar _rec lft(word(_rec,'.',1)+' ',9)+&
lft(word(_rec,'.',2)+' ',9)+&
lft(word(_rec,'.',3)+' ',9)+&
rht(' ![finfo(_rec,'extents')]',9)+&
rht(' ![finfo(_rec,'eof')]',13)+&
rht(' ![finfo(_rec,'sectors')]',15)
echo !_rec
setvar _c2 _c2+1
endif
setvar _c _c+1
endwhile
echo Total Files: !_eof Total Files Displayed: !_c2
purge tempf,temp
deletevar _c,_c2,_eof,_rec
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|