Greg,
If you are looking for a 'Pause' command, Sleeper does not have one. The
best way would be to stop the job and restart it.
One of the files included in the 'Sleeper Distribution', named "SLEEPCMD"
is designed to START, STOP, and WAKEUP sleeper. Although it represents the
setup in our site, it can very easily be 'customized' for any other site.
I'm attaching the latest version of said file, where all needed
customization settings have been grouped into a single section.
The indicated command file can be used for the following:
1. Start Sleeper. It will stream the batch job, making sure that
another instance of sleeper is not running.
2. Stop Sleeper. It uses the Sleeper maintenance utility to send a
termination request to the batch job.
3. Wakeup Sleeper. Cause Sleeper to interrupt its timed read against
a message file and cycle through the schedule.
Items 2 & 3 will work ONLY if sleeper has been set up with an IPC file
for receiving requests from the online maintenance utility.
Regards
Paul Christidis
-----------------------------------------Start Cut *+1
parm slpropt = "?"
echo !hpfile Sleeper option = !slpropt
setvar _slp_Opt UPS("!slpropt")
if pos(",!_slp_Opt,",",START,STOP,WAKEUP,") = 0 then
echo
echo Usage:
echo START - Initiates the SLEEPER scheduler.
echo STOP - Terminates SLEEPER gracefully.
echo WAKEUP - 'Wakes Up'/Cycles SLEEPER.
echo
echo
else
#
# ** Customize following to match you site's setup **
#
setvar _slp_ExecAcct "SYS"
setvar _slp_StrmFile "SLEEPERJ.SYSUTIL.SYS"
setvar _slp_JobCard "SCHEDULR,SLEEPER.SYS"
setvar _slp_MsgFile "SLEEPMSG.DATA.SYS"
setvar _slp_StrmCmnd "JSTREAM.UTIL.SYS"
setvar _slp_MaintUtl "SLEEPER1.SYSUTIL.SYS"
#
echo Acting on: "!_slp_opt"
echo
purge slpfile,temp > $null
build slpfile;rec=-80,,f,ascii;disc=500;temp;msg
file sh = slpfile,oldtemp
showjob [log in to unmask] > *sh
setvar _slp_Exec false
while FINFO("*sh",'eof') <> 0 AND NOT _slp_Exec do
INPUT _slp_Text;wait=2 < *sh
setvar _slp_Exec POS(_slp_JobCard, _slp_Text) <> 0
endwhile
reset sh
#
if _slp_Opt = "START" then
if _slp_Exec then
echo
echo Warning: An instance of SLEEPER is already executing.
echo
else
!_slp_StrmCmnd !_slp_StrmFile
endif
else
if _slp_Exec then
file sleepmsg = !_slp_MsgFile
if _slp_Opt = "STOP" then
run !_slp_MaintUtl;parm=6;info="ABORT"
else
run !_slp_MaintUtl;parm=6;info="WAKEUP"
endif
reset sleepmsg
else
echo
echo Warning: SLEEPER NOT running, Stop/Wakeup not valid.
echo
endif
endif
endif
deletevar _slp_@
----------------------------------------- End Cut *-1
Hello All,
How do I temporarily stop the sleeper program? I cannot find this answer
anywhere online.
Thanks,
--GREG--
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|
