Subject: | |
From: | |
Reply To: | |
Date: | Wed, 8 Nov 2000 09:22:14 -0800 |
Content-Type: | text/plain |
Parts/Attachments: |
|
|
Thanks to many of you for the reminders about HP3000-L stripping file
attachments (sheepish)... here's the command file, in its entirety. Keep in
mind that it does make liberal use of CI variables and some of these should
be changed if they cause conflict within your MPE environment.
PARM FILE="..",FOLDER="",LABELS="NO",PURGEYES="NO"
COMMENT ---- LEVEL A ----
SETVAR ESC CHR(27)
SETVAR FILE1 UPS("!FILE")
SETVAR PURGEYES1 UPS("!PURGEYES")
SETVAR CONFIRM "Confirm File Transfer"
SETVAR LABELS1 UPS("!LABELS")
SETVAR MSG1 "File Transferred:"
SETVAR MSG2 "Dest Folder:"
SETVAR MSG3 "Labels:"
SETVAR ULON "&dD"
SETVAR BOLDON "&dB"
SETVAR NORMAL "&d@"
SETVAR U1 "!ESC!ULON"
SETVAR N1 "!ESC!NORMAL"
SETVAR B1 "!ESC!BOLDON"
SETVAR Y "YES"
SETVAR N "NO"
SETVAR B "BIN"
SETVAR RBSBegin "!ESC&o2G"
SETVAR RBSEnd "!ESC&oH"
IF "!FILE" = ".." OR NOT &
( "!LABELS1" = "YES" OR "!LABELS1" = "NO" OR "!LABELS1" = "BIN" ) OR NOT
&
( "!PURGEYES1" = "YES" OR "!PURGEYES1" = "NO" )
ECHO Example: TRANSFER Filename [Dest PC Folder]
ECHO [Labels !U1!Y!N1|!U1!N!N1|!U1!B!N1]
ECHO [Overwrite !U1!Y!N1|!U1!N!N1]
ELSE
COMMENT ---- LEVEL B ----
IF NOT FINFO("!FILE1",0)
ECHO "!B1!FILE1!N1 DOES NOT EXIST--TRANSFER ABORTED"
ELSE
SETVAR NEWFOLDER "!FOLDER"
IF RHT("!FOLDER",1) <> "\"
SETVAR NEWFOLDER "!FOLDER\"
ENDIF
COMMENT --- the following is Reflection Basic
ECHO !RBSBegin
ECHO Function BrowseForFolder ()
ECHO Dim folder As String
ECHO with application
ECHO folder = .GetFolderName(, "Select Target Folder", "c:\")
ECHO end with
ECHO BrowseForFolder = folder
ECHO End Function
ECHO
ECHO Sub Main
ECHO Dim FileName As string
ECHO Dim Folder as String
ECHO Dim Result as Integer
ECHO Dim CR as String
ECHO FileName = "!FILE1"
ECHO CR = Chr$(rcCR)
IF "!FOLDER" = ""
ECHO Folder = BrowseForFolder
ECHO if Folder = "" then exit sub
ELSE
ECHO Folder = "!NEWFOLDER"
ENDIF
IF "!PURGEYES1" = "YES"
SETVAR Delete "rcDelete"
else
SETVAR Delete "rcAskUser"
ENDIF
SETVAR DestFile "!FILE1"
IF "!LABELS1" = "YES"
SETVAR TransferType "rcLabels"
else
if "!LABELS1" = "BIN"
SETVAR TransferType "rcBinary"
else
SETVAR TransferType "rcAscii"
endif
ENDIF
ECHO if Result = 2 then exit sub
ECHO
ECHO with application
ECHO if right(folder,1)<>"\" then folder=folder+"\"
ECHO .wrqreceivefile Folder & "!DestFile", "!FILE1", !TransferType,
!Delete
ECHO MsgBox "!MSG1 !FILE " & CR & "!MSG2 " & Folder & CR & "!MSG3
!LABELS"
ECHO .transmit CR
ECHO end with
ECHO
ECHO End Sub
ECHO !RBSEnd
COMMENT --- end Reflection Basic
ENDIF
COMMENT ---- END LEVEL B ----
ENDIF
COMMENT ---- END LEVEL A ----
-----Original Message-----
From: EBEN YONG
Sent: Tuesday, November 07, 2000 4:28 PM
To: HP-3000 Systems Discussion (E-mail)
Subject: TRANSFER command file
Hello -
For what it's worth, here's a command file that I have found helpful. It's
a simple file transfer utility that sends a file from the host --> PC using
Reflection-based emulators. You must have a version of Reflection1 that
support RBS scripts (I think v6 and newer). I wrote this because I wanted a
"command-line" method of accomplishing file transfers from the MPE prompt
and I also wanted to learn a few things about host-based RBS scripts. I
know there are multiple variations of these utilites, but here it is anyhow.
Lots of thanks to WRQ for their product and tech support (you can find a
good amount of info off their website: www.wrq.com).
Installation: just put the command file somewhere in your HPPATH (one
method is save the attachment as c:\transfer.cmd2, then log into your e3000
using Reflection, call up the command window - ALT+Y - then type "send
c:\transfer.cmd2 to transfer.pub rec=80" sans quotes). Once you've got the
command file where you want it, type:
TRANSFER [filename]
Typing TRANSFER by itself will give you slightly more information:
Example: TRANSFER Filename [Dest PC Folder]
[Labels YES|NO|BIN]
[Overwrite YES|NO]
Eben Yong
Health Plan of San Mateo
|
|
|