You might also find these command files useful. The intent is that you
set your fkeys via the terminal screen, save them to the file of your
choice with FKEYSAVE and restore from the file of your choice with
FKEYSET.
PARM FILE='FKEY'
COMMENT FILE=FKEYSAVE.CMD
ECHO COMMENT FKEYSAVE CREATED THIS FILE > !FILE
SETVAR ESC CHR(27)
COMMENT BEGIN USER FKEY DEFINITION MODE
ECHO !'ESC'j
SET ECHO=OFF
COMMENT HOME CURSOR AND READ PF1.
INPUT FKEY_1;PROMPT='!"ESC"H!"ESC"d'
COMMENT APPEND TO SAVE FILE
ECHO SETVAR FKEY_1 '!FKEY_1' >> !FILE
COMMENT READ PF2 THRU PF8.
SETVAR FKEY 2
WHILE FKEY <= 8
INPUT FKEY_!FKEY;PROMPT='!"ESC"d'
COMMENT APPEND TO SAVE FILE
ECHO SETVAR FKEY_!FKEY '![FKEY_!FKEY]' >> !FILE
SETVAR FKEY FKEY+1
ENDWHILE
SET ECHO=ON
COMMENT END USER FKEY DEFINITION MODE
ECHO !'ESC'k
COMMENT END FKEYSAVE.CMD
PARM FILE='FKEY'
COMMENT FILE=FKEYSET.CMD
SETVAR ESC CHR(27)
COMMENT SET VARS TO SAVED FKEYS
XEQ !FILE
SETVAR FKEY 1
WHILE FKEY <= 8
ECHO ![FKEY_!FKEY]
SETVAR FKEY FKEY+1
ENDWHILE
COMMENT ENABLE USER KEYS
ECHO !'ESC'&jB
COMMENT END FKEYSET.CMD