"Paul H Christidis" <[log in to unmask]> wrote:
> Fellow list members,
>
> Does anyone know if there exists an 'finfo' option that can be used to
> determine the existence of an ACD against a file (In MPE/iX not MPEX).
>
Paul,
I wrote the following script to locate files with ACDs. I use it after
operating system updates. Occasionally Patch/iX puts ACDs on files in
PUB.SYS. I have seen ACDs on KSAMUTIL and QUERY that prevented non-SM users
from running them. The script works against any file set that LISTFILE can
and will produce a list of files with ACDs. I never added the functionality
to display what the ACDs are, I just wanted to know of their existence.
Perhaps it will suit your needs.
parm fileset="@",_entry="MAIN"
#
# Check a fileset for ACDs. Useful after an operating
# system update for files in PUB.SYS and HPBIN.SYS
#
if "!_entry"="MAIN" then
echo
echo The following files have ACDs on them
purge chkacdw,temp >$NULL
file chkacdw;rec=-120,,f,ascii;disc=500000;nocctl
listfile !fileset,-2 >*chkacdw
!hpfile !fileset,"OUTPUTFILE" <chkacdw
echo *********** END OF LIST *******************
return
endif
if "!_entry"="OUTPUTFILE" then
input _listfile
echo !_listfile
input _listfile
input _listfile
input _listfile
setvar _HFS,false
if pos(str("!fileset",1,1),"./") > 0 then
setvar _HFS,true
endif
setvar _numrecs,finfo(HPSTDIN,"EOF") - 3
while setvar(_numrecs,_numrecs-1) > 0 do
input _listfile
if pos("NO ACDS",_listfile) = 0 then
if _HFS then
setvar _fname, str("!_listfile",40,60)
else
setvar _fname,str("!_listfile",1,10)
endif
if len(rtrim("!_fname")) > 0
echo !_fname
endif
endif
endwhile
endif
Usage:
:chkacds /WERTH/PUB/@
The following files have ACDs on them
PATH= /WERTH/PUB/
.sh_history
FOO
RESULT
TS
UPLOAD
hfs/
rec132b
xl
*********** END OF LIST *******************
HTH.
Doug.
Doug Werth Beechglen Development Inc.
[log in to unmask] Cincinnati, Ohio
|