I've seen several posts on this topic since subscibing and offer this simple
set of command files as a beginning point for monitoring jobs completions in
a log file.

Here is a command file I began using last year to track job completions. It
is inserted into our jobstreams before any EOJ command.  I have substituted
the requirements Holger specified in place of my own info requirements.  In
addition to tracking job completions it also tests for any Command
Interpreter errors and prompts for attention by issuing a Tellop to the
console. We found a few errors that we decided to globally ignore, and some
other job changes were required to reset errors and warnings within specific
jobstreams. I have since enhanced this by using our email interface to send
an email-page to the operator/on-call person whenever an error condition
occurs.


USER DEFINED COMMAND FILE:  ENDJOB.PUB.SYS

SHOWJCW
SHOWVAR HPCIERRMSG
IF CIERROR = 383 OR CIERROR = 4809 OR CIERROR = 431 THEN
   SETJCW CIERROR 0
ENDIF
FILE JLOG=JL!HPYEAR!HPMONTH!HPDATE.JOBLOG.SYS,OLD;ACC=APPEND
IF CIERROR <> 0 THEN
  TELLOP *************************************
  TELLOP * !HPJOBNAME HAS AN ERROR CONDITION *
  TELLOP *************************************
  ECHO !HPJOBNAME J!HPJOBNUM !HPTIMEF !HPDATEF !HPSTREAMEDBY !HPCIERR >*JLOG
ELSE
  TELLOP *************************************
  TELLOP * !HPJOBNAME COMPLETED SUCCESSFULLY *
  TELLOP *************************************
  ECHO !HPJOBNAME J!HPJOBNUM !HPTIMEF !HPDATEF !HPSTREAMEDBY !HPCIERR >*JLOG
ENDIF
RESET JLOG

I build a file each day at midnight using this jobstream in a group called
JOBLOG in the SYS account.

!JOB JLGINITJ,MANAGER.SYS,JOBLOG;OUTCLASS=LP,1,1;HIPRI
!COMMENT *****************************************
!COMMENT * THIS JOB PREPARES A NEW LOG FILE FOR  *
!COMMENT * TRACKING PRODUCTION JOB COMPLETIONS   *
!COMMENT *****************************************
!
!BUILD JL!HPYEAR!HPMONTH!HPDATE;REC=-80,1,F,ASCII;DISC=2000
!
!RELEASE JL!HPYEAR!HPMONTH!HPDATE.JOBLOG.SYS
!
!ENDJOB
!EOJ

This command file is used to provide a quick view of today's joblog file.

User-defined command: JOBLOG.JOBLOG.SYS

PRINT JL!HPYEAR!HPMONTH!HPDATE.JOBLOG.SYS;PAGE=0

The processes above tracks jobs that have reached EOJ very well, but it does
depend on some basic programming techniques that call an error instead of
simply allowing a job to flush.  I have a separate process and log file that
tracks job logons and a background job that compares the log to a showjob
command every 5 minutes to detect any jobs that have flushed.  It depends on
Qedit and Suprtool products and needs some work, but I will gladly share it
in a separate message if your interested.

Budd Marsh
HP Systems Administrator
Multiple Zones Int'l



-----Original Message-----
From: Holger Schroers, QVC Germany
[mailto:[log in to unmask]]
Sent: Saturday, July 22, 2000 4:26 AM
To: [log in to unmask]
Subject: [HP3000-L] Write like a log to a special file


Hi anyone around this world!
I found out that this newsgroup seems to be a very important
and usefull resource for my unsolved problems and ideas...
Here we go with another one:

    I want to create a daily log-file which keeps the information
    of processed jobs and streams.
    Has MPEX a possibility to support this idea?
    What I want to do is:

    A lot of jobs, may be all, should write a central log-file
    with their name (and user who started the job) and time
    and some other informations.

    Is it possible like in MSDOS (sorry for that comparison) to ECHO
    a text or system-variable (like HPDATE or HPTIME) to a
    special file?

    In DOS I know its easy to do:
        ECHO Job (JOB XYZ) started at %TIME%, %DATE% by %USER% >>
LOGFILE.TXT

    where the end "> LOGFILE" would create a new file
    and ">> LOGFILE" will append the existing file.

    And this operates very good in MSDOS if you predefine the %...%
variables...with SET VARIABLE=....
    Is there something comparable on HP under MPEX ?
    Otherwhise I want to create a small programm callable inside the job to
read the system-variables
    and write them through the program to the log-file, but it might be
easier...!?

    I know that there is a system-log-file but this keeps too much unwanted
lines and logeentries
    and is not usefull for our analyzings.

Thanks for every hint or solution!

Holger Schrörs
QVC Germany
MIS International