> -----Original Message-----
> From: John Backus [SMTP:[log in to unmask]]
> Sent: Thursday, May 18, 2000 2:11 PM
> To: [log in to unmask]
> Subject: Re: Volutil in Batch
>
> Joe,
>
> Thanks, perhaps you might share the, "3/2000 tested in production under
> 5.5 PP7" and the other command files to the list?
>
> John
> Beechglen.com
>
Below are the other 2 files associated with VOLCRT. I use VOLSCRAT
and VOLCRT when I have to replace a disk drive on our Shadowed system as
that system is not mirrored. These commands are used to rebuild the volume
set prior to running the BLDJOB commands. Our volume set has 108 volumes in
it and to rebuild by hand is very time consuming. The 3rd command VOLADD is
used if the volume set already exists and I just want to add additional
drives.
VOLSCRAT
PARM P1=$NULL, P2=$NULL, P3=$NULL
COMMENT *********************************************************
COMMENT * COMMAND: VOLSCRAT.COMMAND.SYS *
COMMENT * *
COMMENT * PURPOSE: SCRATCH SEQUENTIAL NUMBERED LDEVS WITHING A *
COMMENT * SPECIFIED VOLUME SET. *
COMMENT * *
COMMENT * PARMS: P1 - VOLUME SET NAME *
COMMENT * P2 - BEGINNING LDEV NUMBER TO SCRATCH *
COMMENT * P3 - ENDING LDEV NUMBER TO SCRATCH *
COMMENT * *
COMMENT * CALLED BY: CAN RUN IN STAND ALONE MODE WITH OR *
COMMENT * WITHOUT PARAMETERS. *
COMMENT * *
COMMENT * *
COMMENT *********************************************************
SETVAR VOL_NAME "!P1"
SETVAR BEG_LDEV "!P2"
SETVAR END_LDEV "!P3"
ECHO ![CHR(27)+"h"+CHR(27)+"J"]
ECHO
ECHO
ECHO
ECHO
ECHO
ECHO
ECHO
ECHO VOLUME SET SCRATCH UTILITY
ECHO
ECHO
ECHO
ECHO
IF "!VOL_NAME" = "$NULL" THEN
ECHO
INPUT VOL_NAME, "ENTER THE VOLUME NAME: "
INPUT BEG_LDEV, "ENTER THE BEGINNING LDEV #: "
INPUT END_LDEV, "ENTER THE ENDING LDEV #: "
ECHO
ENDIF
WHILE !BEG_LDEV > !END_LDEV
ECHO
ECHO *** BEGINNING LDEV MUST BE LESS THAN ENDING LDEV ***
ECHO
INPUT BEG_LDEV,"ENTER THE BEGINNING LDEV # [!BEG_LDEV]: "
INPUT END_LDEV, "ENTER THE ENDING LDEV # [!END_LDEV]: "
ENDWHILE
ECHO ![chr(27)+"h"+chr(27)+"J"]
ECHO
ECHO
ECHO BASED ON YOUR INPUT THE FOLLOWING VALUES WILL BE USED BY VOLUTIL
ECHO
ECHO VOLUME_NAME : !VOL_NAME
ECHO BEGINNING LDEV : !BEG_LDEV
ECHO ENDING LDEV : !END_LDEV
ECHO
ECHO
SETVAR RESP, "N"
INPUT RESP,"IF THIS IS CORRECT PRESS Y[!RESP]: "
WHILE "!RESP" <> "Y"
ECHO
INPUT VOL_NAME, "PLEASE ENTER THE VOLUME NAME[!VOL_NAME]: "
INPUT BEG_LDEV, "PLEASE ENTER THE BEGINNING LDEV #[!BEG_LDEV]: "
INPUT END_LDEV, "PLEASE ENTER THE ENDING LDEV #[!END_LDEV]: "
ECHO
INPUT RESP,"IF THIS IS CORRECT PRESS Y[!RESP]: "
SETVAR RESP UPS(RESP)
ENDWHILE
SETVAR CURR_LDEV BEG_LDEV
ECHO VERIFY OFF > VOLIN
WHILE (!CURR_LDEV <= !END_LDEV)
ECHO SCRATCHVOL !CURR_LDEV >>VOLIN
SETVAR CURR_LDEV !CURR_LDEV + 1
ENDWHILE
ECHO EXIT >> VOLIN
ECHO
ECHO
SETVAR REQ "N"
INPUT REQ,"WOULD YOU LIKE TO SEE THE VOLUTIL COMMANDS AS THEY &
WILL BE EXECUTED?[!REQ]: "
IF UPS("!REQ") = "Y" THEN
ECHO
PRINT VOLIN
ENDIF
ECHO
ECHO MEMBER NUMBERS WILL BE IN SEQUENTIAL ORDER
ECHO
SETVAR ANS "N"
INPUT ANS,"LAST CHANCE TO ABORT VOLSCRAT COMMAND. PRESS Y TO CONTINUE &
[!ANS]: "
SETVAR ANS UPS(ANS)
IF "!ANS" <> "Y" THEN
RETURN
ENDIF
VSCLOSE !VOL_NAME;NOW
ECHO WAITING ON VOLUME SET TO BE CLOSED (3 MINS)
PAUSE 180
VOLUTIL < VOLIN
ECHO
ECHO
ECHO LDEV !BEG_LDEV THROUGH LDEV !END_LDEV HAS BEEN SCRATCHED
ECHO
PURGE VOLIN
=======================================================================
VOLADD
PARM P1=$NULL, P2=$NULL, P3=$NULL, P4=$NULL
COMMENT *********************************************************
COMMENT * COMMAND: VOLADD.COMMAND.SYS *
COMMENT * *
COMMENT * PURPOSE: ADD A NEW DRIVE TO AN EXISTING VOLUME SET *
COMMENT * LDEVS MUST BE IN SQUENTIAL LDEV NUMBERS. *
COMMENT * *
COMMENT * PARMS: P1 - VOLUME SET NAME *
COMMENT * P2 - BEGINNING LDEV NUMBER TO SCRATCH *
COMMENT * P3 - ENDING LDEV NUMBER TO SCRATCH *
COMMENT * *
COMMENT * CALLED BY: CAN RUN IN STAND ALONE MODE WITH OR *
COMMENT * WITHOUT PARAMETERS. *
COMMENT * *
COMMENT * *
COMMENT *********************************************************
SETVAR VOL_NAME "!P1"
SETVAR BEG_LDEV "!P2"
SETVAR END_LDEV "!P3"
SETVAR MBR_NUM "!P4"
IF "!VOL_NAME" = "$NULL" THEN
ECHO ![chr(27)+"h"+chr(27)+"J"]
INPUT VOL_NAME, "PLEASE ENTER THE VOLUME NAME: "
INPUT BEG_LDEV, "PLEASE ENTER THE BEGINNING LDEV #: "
INPUT END_LDEV, "PLEASE ENTER THE ENDING LDEV #: "
INPUT MBR_NUM, "PLEASE ENTER STARTING MEMBER #: "
ECHO
ENDIF
WHILE !BEG_LDEV > !END_LDEV
ECHO
ECHO *** BEGINNING LDEV MUST BE LESS THAN ENDING LDEV ***
ECHO
INPUT BEG_LDEV,"PLEASE ENTER THE BEGINNING LDEV # [!BEG_LDEV]: "
INPUT END_LDEV, "PLEASE ENTER THE ENDING LDEV # [!END_LDEV]: "
ENDWHILE
ECHO ![chr(27)+"h"+chr(27)+"J"]
ECHO
ECHO BASED ON YOUR INPUT THE FOLLOWING VALUES WILL BE USED BY VOLUTIL
ECHO
ECHO VOLUME NAME : !VOL_NAME
ECHO BEGINNING LDEV : !BEG_LDEV
ECHO ENDING LDEV : !END_LDEV
ECHO STARTING MEMBER #: !MBR_NUM
ECHO
SETVAR RESP "N"
INPUT RESP,"IF THIS IS CORRECT PRESS Y[!RESP]: "
SETVAR RESP UPS(RESP)
WHILE "!RESP" <> "Y"
ECHO ![chr(27)+"h"+chr(27)+"J"]
INPUT VOL_NAME, "PLEASE ENTER THE VOLUME NAME[!VOL_NAME]: "
INPUT BEG_LDEV, "PLEASE ENTER THE BEGINNING LDEV #[!BEG_LDEV]: "
INPUT END_LDEV, "PLEASE ENTER THE ENDING LDEV #[!END_LDEV]: "
INPUT MBR_NUM, "PLEASE ENTER STARTING MEMBER #[!MBR_NUM]: "
ECHO
SETVAR RESP "N"
INPUT RESP,"IF THIS IS CORRECT PRESS Y[!RESP]: "
SETVAR RESP UPS(RESP)
ENDWHILE
ECHO VERIFY OFF > VOLIN
WHILE (!BEG_LDEV <= !END_LDEV)
ECHO NEWVOL !VOL_NAME:MEMBER!MBR_NUM !BEG_LDEV 100 100 >>VOLIN
SETVAR MBR_NUM !MBR_NUM + 1
SETVAR BEG_LDEV !BEG_LDEV + 1
ENDWHILE
ECHO EXIT >>VOLIN
ECHO
SETVAR REQ "N"
INPUT REQ,"WOULD YOU LIKE TO SEE THE VOLUTIL COMMANDS AS THEY &
WILL BE EXECUTED?[!REQ]: "
IF UPS("!REQ") = "Y" THEN
ECHO
PRINT VOLIN
ENDIF
ECHO
ECHO
SETVAR ANS "N"
INPUT ANS,"LAST CHANCE TO ABORT VOLADD COMMAND. PRESS Y TO CONTINUE &
[!ANS]: "
IF "!ANS" <> "Y" THEN
RETURN
ENDIF
VOLUTIL <VOLIN
PURGE VOLIN,TEMP
ECHO
ECHO
ECHO VOLCRT COMPLETE!!!
ECHO
|