WirtAtmar wrote:
>
> The console messages aren't a necessary condition of the Keep Alive
> circuit, merely icing on the cake. A small job sending a message to
> Port 20's session every 90 seconds would be all that's necessary,
> regardless of whether or not it was the console at the moment.
>
> I would suggest the message be "Esc A CR LF". This message would
> cause the cursor on the terminal to simply recycle in place.
>
> What would kill the circuit would be if someone should sign on to
> another session on the Port 20/console terminal. The Keep Alive job
> would have to be restarted with the new session number entered.
> Alternatively, with 10 minutes more programming, the program could be
> made to seek out and find the session number of the Port 20 device
> automatically. The only killer would then be that someone would
> simply sign the terminal off by doing a ":BYE". But I would suspect
> you'd find that out in about two minutes :-).

I think this job may fill all the requirements.  I've even already
tested it!  (although I couldn't get Esc-A to work in the TELL
statement):

!JOB IAMALIVE, MANAGER.SYS; HIPRI; OUTCLASS=LP, 1, 1
!
!##########################################################
!#
!#  IAMALIVE - TIM ERICSON, DENKOR DENTAL MANAGEMENT CORP.
!#
!#    THIS JOB SENDS A MESSAGE TO LDEV 20 EVERY X SECONDS,
!#    AS DEFINED IN THE 'PAUSE' STATEMENT, BELOW.
!#
!##########################################################
!
!FILE CONSOLE; DEV=20
!
!WHILE 1 = 1
!
!  SHOWDEV 20 > SDFILE
!
!  PRINT SDFILE; START=2; > PRFILE
!  INPUT SDREC < PRFILE
!  SETVAR AVAIL, STR ( SDREC, 11, 8 )
!
!  IF "!AVAIL" = "AVAIL"
!
!    ECHO I AM ALIVE AT !HPTIMEF >> TERM20
!    FCOPY FROM=TERM20; TO=*CONSOLE; CHAR; NORECNUM
!    PURGE TERM20, TEMP
!
!  ELSE
!
!    SETVAR SESSION, STR ( SDREC, 25, POS ( ":", SDREC ) - 25 )
!    TELL !SESSION I AM ALIVE AT !HPTIMEF
!
!  ENDIF
!
!  PURGE SDFILE, TEMP
!  PURGE PRFILE, TEMP
!
!  PAUSE 90
!
!ENDWHILE
!
!EOJ

Cheers!

  +------------------------------------------------------------------+
   My mind is my own, as are my ideas and opinions.
   My heart, body, and soul, however, all belong to others.      Tim.
  +------------------------------------------------------------------+
   Tim Ericson            tericson     DenKor Dental Management Corp.
   Sr. Programmer/Analyst   at denkor   (aka Willamette Dental Group)
     (& Systems Manager)      dot com    503-526-4440 (direct number)
   Programming HP3000s since 1983!          http://www.denkor.com
  +------------------------------------------------------------------+