Bellow is a sample using (Cognos Powerhouse) Quiz.
You can do similar functions using the CI replacing the Quiz portion.

hth...

mc

!JOB LABTRAN1,MGR.ACCT;PRI=CS
:
!COMMENT ---------------------------------------
!COMMENT   BATCH JOB TO TRANSFER SUNQUEST
!COMMENT   LAB CHARGES - THIS STEP CREATES THE
!COMMENT   BATCH JOB (I.E. USING QUIZ TO SEL
!COMMENT   THE DATE)
!COMMENT ---------------------------------------
:
!FILE QUIZLIST=$NULL
:
!PURGE LABTRAN2 > $NULL
!PURGE LABTRAN3 > $NULL
:
!QUIZ

;----------------------------------------------
;  CREATE FTP PROCESS
;----------------------------------------------

ACC ENTITY-CTRL

SET REPORT DEV DISC NAME LABTRAN2

SEL IF ENTITY-ID = "01"

DEF DT-1 NUM*6 = DATE((DAYS(SYSDATE)) -1)

DEF DT-2 CHAR*6 = ASCII(DT-1,6)

DEF DT-3 CHAR*8 = PACK("bl" + & ;
  DT-2[3:2] + DT-2[5:2] + DT-2[1:2])

DEF F-IN CHAR*12 = DT-3 + ".dat"

DEF F-OUT CHAR*8 = "bl" + DT-2

SET REPORT NOHEAD
SET PAGE LENGTH 1 WIDTH 80
SET REPORT SPACING 0

REPORT & ;
  "user user password" SKIP & ;
  "get " F-IN " " F-OUT SKIP & ;
  "exit"

GO

;----------------------------------------------
;  CREATE FTP PROCESS
;----------------------------------------------

SET REPORT DEV DISC NAME LABTRAN3

REPORT & ;
  "copy " F-OUT ",LAB.DATA"

GO

EXIT
:
!COMMENT ---------------------------------------
!COMMENT   CHANGE TO DAT DIRECTORY AND
!COMMENT   DOWNLOAD FILE
!COMMENT ---------------------------------------
:
!CHGROUP DAT
:
!FILE FTPIN=LABTRAN2.DATA
!RUN FTP.ARPA.SYS;INFO="190.182.64.32";STDIN=*FTPIN
:
!XEQ LABTRAN3.DATA
:
!COMMENT ---------------------------------------
!COMMENT   CLEANUP WORKFILES
!COMMENT ---------------------------------------
:
!CHGROUP DATA
:
!PURGE LABTRAN2 > $NULL
!PURGE LABTRAN3 > $NULL
:
!EOJ



> Mike Church
> Technical Support Manager
> Information Services
> Our Lady of Bellefonte Hospital
> Saint Christopher Drive
> Ashland, Kentucky 41101
> -----------------------------------
> Phone : (606)833-3727
> Pager : (606)327-0965
>   Fax : (606)833-3342
> -----------------------------------
>    Alternate e-mail : [log in to unmask]
> -----------------------------------
>  MY URL: http://members.tripod.com/mike_church/
> OLBH: http://www.olbh.com
> -----------------------------------
> Daily Quote: Few are those who see with their own eyes and feel with their
own hearts. - Albert Einstein
>
>
>


-----Original Message-----
From: Vijesh [mailto:[log in to unmask]]
Sent: Saturday, July 29, 2000 2:42 PM
To: [log in to unmask]
Subject: [HP3000-L] Help: FTP


Greetings!

Looking for help from all the GURUs out there!

A client of ours would FTP a txt file to my server (running winnt 4.0), this
is a daily process and the txt file will be named "DDMMYY.txt"(where ddmmyy
will be day,month and year). I have to transfer the daily file from the NT
server to a HP3000 host with a fixed file name, lets say "xx12".

Need help on how to automate this process of FTP to HP3K, since the source
file name is variable and assuming there could be multiple files in the
source directory on the NT server. I am required to pick only the current
days file (ddmmyy.txt), ignore other files and FTP it to HP3K.