This job will do exactly what you are looking to do.

!JOB ABORTSES,OPERATOR.SYS;INPRI=13;PRI=CS
!
!COMMENT *********************************************************
!COMMENT *  ABORTS ALL SESSIONS AT THE START OF THE NIGHT TIME
!COMMENT *  SCHEDULE.
!COMMENT *
!COMMENT *  NOTE:  FOLLOWING SESSIONS ARE NOT ABORTED:
!COMMENT *          LDEV 20 AND 21, 601, 602
!COMMENT *          USERID OF MANAGER IN ALL ACCOUNTS.
!COMMENT *********************************************************
!
!TELL @ NIGHTLY SCHEDULE STARTING. PLEASE LOG OFF NOW!!!
!TELL @ NIGHTLY SCHEDULE STARTING. PLEASE LOG OFF NOW!!!
!TELL @ NIGHTLY SCHEDULE STARTING. PLEASE LOG OFF NOW!!!
!PAUSE 30
!
!COMMENT *********************************************************
!COMMENT * ABORT SESSIONS USING ABORTJOB COMMAND.
!COMMENT *********************************************************
!SHOWJOB JOB=@S
!
!PURGE ABORTSE1
!FILE ABORTSE1;REC=-80,,F,ASCII;NOCCTL;SAVE
!SHOWJOB JOB=@S >*ABORTSE1
!RESET ABORTSE1
!QUAD
TEXT ABORTSE1
KEEP ABORTSE1:U(ALL INCLUDING "EXEC"(9/12))
YES
TEXT ABORTSE1
DELETE ALL INCLUDING " 20  20 "
DELETE ALL INCLUDING " 21  21 "
DELETE ALL INCLUDING "601  601"
DELETE ALL INCLUDING "602  602"
DELETE ALL INCLUDING "MANAGER."
CHANGE 9/80 TO "" ALL
CHANGE 1 TO "ABORTJOB " ALL
KEEP ABORTSE1:U
YES
EXIT
!SETVAR HPAUTOCONT TRUE
!IF FINFO("ABORTSE1","EOF") > 0
!  XEQ ABORTSE1
!ENDIF
!SETVAR HPAUTOCONT FALSE
!
!COMMENT *********************************************************
!PAUSE 120
!SHOWJOB JOB=@S
!SHOWJOB JOB=@J
!
!EOJ



Jeff Sullivan
[log in to unmask]