Larry,

  Reflection file transfers require running a host program
(PCLINK/PCLINK2/etc) to communicate with the PC and facilitate transfers.
Since Security/3000 menus by design restrict what programs users can :RUN,
you need to add code to your menus to allow transfers to occur.

  Here's what we used in our Security/3000 menus to allow users to do
Reflection file transfers. A similar (but different) menu file allows file
transfers for MS92 users (let me know if you need that).

 -Chris Bartram

COMMENT ---
COMMENT --- REFLMENU: This is a USE file to do file transfers within
COMMENT ---           menus.  To use it, keep it as file REFLMENU and
COMMENT ---           add the following lines to your own menu:
COMMENT ---
COMMENT ---           *CAPTION Reflection Commands
COMMENT ---           USE REFLMENU
COMMENT ---
COMMENT ---
COMMENT --- If you dont have version 3.2 or later of Reflection,
COMMENT --- change the "&oB" to "&oC" and delete the completion
COMMENT --- code checking (see below).
SETVAR REFLECT CHR(27)+"&oB"

ECHO Choose one of the following options:
ECHO
ECHO    SEND a file from the PC to the HP3000
ECHO    RECEIVE a file to the PC from the HP3000
ECHO    Execute an arbitrary COMMAND on the PC
ECHO

SETVAR REFL_CMD "INITIALIZE"
WHILE POS("/"+REFL_CMD+"/","/SEND/RECEIVE/COMMAND/")<=0
   INPUT REFL_CMD; PROMPT="SEND, RECEIVE, or COMMAND? "
   SETVAR REFL_CMD UPS(REFL_CMD)
ENDWHILE

IF REFL_CMD="COMMAND" THEN
   INPUT REFL_CMD; PROMPT="REFLECTION Command? "
   ECHO !REFLECT!REFL_CMD
   COMMENT --- If you don't have Reflection 3.2 or later, delete
   COMMENT --- the following two lines (see above, also).
   INPUT REFLECT_CC; PROMPT=":"
   ECHO REFLECTION Completion Code: !REFLECT_CC
ELSE
   SETVAR PC_FILESPEC ""
   INPUT PC_FILESPEC; PROMPT="PC filespec? "
   SETVAR HP_FILENAME ""
   INPUT HP_FILENAME; PROMPT="HP filename? "
   ECHO
   ECHO    Review the REFLECTIONS manual, for a complete set, of
   ECHO    file transfer options. All options MUST be spelled out
   ECHO    and separated by spaces.
   ECHO      Example: ASCII DELETE
   ECHO
   SETVAR XFER_OPTS ""
   INPUT XFER_OPTS; PROMPT="File transfer options? "
   SETVAR TO_OR_FROM "![IF REFL_CMD='SEND' THEN 'TO' ELSE 'FROM']"
   ECHO &
!REFLECT!REFL_CMD !PC_FILESPEC !TO_OR_FROM !HP_FILENAME !XFER_OPTS
   INPUT MPE_COMMAND; PROMPT=":"
   COMMENT ---
   COMMENT --- Verify that the command sent by REFLECTION is a
   COMMENT --- "RUN PCLINK.PUB.SYS", since this string is user-
   COMMENT --- configurable and we are going to execute it as an
   COMMENT --- MPE command.
   COMMENT --- If you are using PCLINK2, change the following line
   COMMENT --- to IF UPS(MPE_COMMAND[0:19])="RUN PCLINK2.PUB.SYS"
   IF UPS(MPE_COMMAND[0:19])="RUN PCLINK2.PUB.SYS"
      !MPE_COMMAND
      COMMENT --- If you don't have Reflection 3.2 or later, delete
      COMMENT --- the following two lines (see above, also).
      INPUT REFLECT_CC; PROMPT=":"
      ECHO REFLECTION Completion Code: !REFLECT_CC
   ELSE
      ECHO ERROR!
      ECHO After VEMENU transmitted:
      ECHO &
'!REFL_CMD !PC_FILESPEC !TO_OR_FROM !HP_FILENAME !XFER_OPTS'
      ECHO the PC transmitted:
      ECHO '!MPE_COMMAND'
      ECHO rather than
      ECHO 'RUN PCLINK2.PUB.SYS'
   ENDIF
ENDIF


Larry Barnes <mailto:[log in to unmask]> wrote:
> I have an interesting problem.  I have placed users into a Vesoft Menu
> system and now the users involved can't do Reflection File Transfers.
> Does anyone out there know what I need to set to enable these users to
> perform their task?
>
> As always, thanks in advance.
>
> Larry A. Barnes
> Systems Administrator - HP3000

* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *