>What I'd like to do perform a text
>search on files in certain groups.
> I can issue the vesoft %print command
>without a problem.
> But I would like to automate this process... somewhat.

Here's an old command file I use to do this. Probably could be more
elegant but since it works I leave it alone!

===============================
SCAN.COMMAND.SYS

parm p1=23
if not hpinteractive and p1 = 23
   setvar pagelen 60
else
   setvar pagelen !p1
endif
run mpex.pub.vesoft;parm=1;info="scancoms"
===============================
SCANCOMS.COMMAND.SYS

%setvar ignorecase = " "
%setvar fileset    = " "
%setvar searchcl   = " "
%setvar scanstring = readstring("Enter string         :")
%while scanstring <> ""
%   setvar ignorecase = readstring("Ignore case (Y/N)?   :")
%   if ups(ignorecase) = "N" then
%      setvar searchcl = "search="
%   else
%      setvar searchcl = "search=cl"
%   endif
%   setvar fileset = readstring("Enter fileset        :")
%   setvar printdev = "STDLIST"
%   while printdev <> ""
%      setvar printdev = readstring &
         ("Output at  ["+str("!printdev"+"        ",1,8)+"]:")
%      if ups(printdev) = "STDLIST" or printdev = ""
%         file scanlist=$stdlist
%      else
%         setjcw cierror 0
%         continue
%         file scanlist=!hpjobname;dev=!printdev;cctl
%         if cierror = 0
%            setvar printdev = ""
%         else
%            setvar printdev = "STDLIST"
%         endif
%      endif
%   endwhile
%   if fileset <> "" then
%      print !fileset; !searchcl "!scanstring" &
         ;num;page=!pagelen ;nofilepagebreak >*scanlist
%   endif
%   echo
%   setvar scanstring = readstring("Enter string         :")
%endwhile
%deletevar scanstring
%deletevar ignorecase
%deletevar fileset
%deletevar searchcl
%deletevar printdev
%reset scanlist
===============================

John Pickering
JWP Systems Inc
Toronto