This should work for you.
build iplist;rec=-79,1,f,ascii;msg;temp
file iplist=iplist,oldtemp
build sortfle;rec=-79,,f,ascii;temp
file sortfle=sortfle,oldtemp
comment ************************************************
comment * Get the list and remove unwanted entries
comment ************************************************
listfile ci.pub.sys,8>iplist
setvar counter (finfo('iplist',"eof"))
while counter > 0
input rec < iplist
if (lft(rec,1)) = '#'
if (str(rec,57,1)) <> 'S'
echo !rec >> *sortfle
endif
endif
setvar counter counter-1
endwhile
comment ***********************
comment * Sort the listings
comment ***********************
build sortcmd;rec=-79,1,f,ascii;temp
file sortcmd=sortcmd,oldtemp
build sortfle2;rec=-79,,f,ascii;temp;msg
file sortfle2=sortfle2,oldtemp
echo I sortfle > sortcmd
echo O sortfle2 >> sortcmd
echo key 63,15,byte >> sortcmd
comment echo key 52,8,byte >> sortcmd
echo end >> sortcmd
run sort.pub.sys;stdin=sortcmd > $null
comment *************************************
comment * Display the listing.
comment *************************************
setvar counter (finfo('sortfle2',"eof"))
setvar display_counter 0
echo
while counter > 0
input rec < sortfle2
if (lft(rec,1)) <> ' '
echo !rec
setvar display_counter !display_counter + 1
endif
setvar counter !counter-1
endwhile
echo
echo !display_counter sessions displayed
echo
comment **********
comment * Clean up
comment **********
purge iplist;temp
purge sortcmd;temp
purge sortfle;temp
purge sortfle2;temp
Life>
DISCLAIMER:
**This E-mail and any of its attachments may contain Lincoln National Corporation proprietary information, which is privileged, confidential, or subject to copyright belonging to the Lincoln National Corporation family of companies. This E-mail is intended solely for the use of the individual or entity to which it is addressed. If you are not the intended recipient of this E-mail, you are hereby notified that any dissemination, distribution, copying, or action taken in relation to the contents of and attachments to this E-mail is strictly prohibited and may be unlawful. If you have received this E-mail in error, please notify the sender immediately and permanently delete the original and any copy of this E-mail and any printout. Thank You.**
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|
