Try this:
parm acct="@"
purge netcheck > $null
purge netchk0 > $null
purge netsort,temp > $null
build netcheck;rec=-80,,f,ascii
build netsort;temp;rec=-80,,f,ascii
file sortnet=netsort;acc=append
echo i netcheck >*sortnet
echo o netchk0 >*sortnet
echo k 57,21 >*sortnet
echo end >*sortnet
file netx=netcheck,old
listf ci.pub.sys,8 >*netx
sort < netsort >$null
purge netcheck >$null
setvar cntr 0
echo ![chr(27)]H ![chr(27)]J
echo Session User Name.Account Ldev / IP
echo ------- -------------------------- ------------------
while setvar(cntr,cntr+1) < finfo("netchk0",19)
print netchk0;start=!cntr;end=!cntr > rec1
input rec2 < rec1
if pos("#S","!rec2")>0
setvar info_str str("!rec2",1,35) + str("!rec2",63,17)
if "!acct" <> "@"
if pos(ups("!acct"),"!info_str")>0
echo !info_str
endif
else
echo !info_str
endif
endif
endwhile
reset netx
reset sortnet
purge netchk0
deletevar cntr
YMMV,
Rich Rankin
Clark County
> -----Original Message-----
> From: Juan Hernandez [mailto:[log in to unmask]]
> Sent: Friday, August 18, 2000 8:26 AM
> To: [log in to unmask]
> Subject: Re: [HP3000-L] ?? MPE script for sessions and ip
>
>
> Great script Larry !, it is really what i was looking for,
> that is why i
> look into this list very often.
> Now, is it much to ask if you can help me to modify it to see
> ip addresses
> only in some account ? (we are in 5.5 pp 7)
>
> Thank you
>
> Juan Hernández
> Sistemas
> CORATEC S.A.
> Chihuahua, Chihuahua, México
> [log in to unmask]
>
|