HP3000-L Archives

October 2006, Week 3

HP3000-L@RAVEN.UTC.EDU
Options: Use Monospaced Font
Show Text Part by Default
Show All Mail Headers

Message: [<< First] [< Prev] [Next >] [Last >>]
Topic: [<< First] [< Prev] [Next >] [Last >>]
Author: [<< First] [< Prev] [Next >] [Last >>]

Print Reply
Subject:
Re: Looking for a listf script
From:
"Miller, Keven" <[log in to unmask]>
Reply To:
Miller, Keven
Date:
Sat, 21 Oct 2006 07:13:33 -0600
Content-Type:
text/plain
Parts/Attachments:
text/plain (91 lines) 
J Dolliver wrote:
> Does anyone have a script that can display files in a list like MPEX that can display
> file create,access and modify dates on one line?  

You can try this one,
Keven Miller


:ldate.cmd a@
Filename                  Fcode      EOF Created  Modified Allocate UL Owner
------------------------- ----- -------- -------- -------- -------- -- --------
AWKLIBC.PDC.KEVENM                   911 10/16/06 10/16/06 10/16/06    MGR.KEVE
AWKLIBH.PDC.KEVENM                    38 10/16/06 10/16/06 10/16/06    MGR.KEVE
AWKMAINC.PDC.KEVENM                   39 10/16/06 10/16/06 10/16/06    MGR.KEVE
AWKMAINP.PDC.KEVENM       NMPRG      184 10/16/06 10/16/06 10/16/06    MGR.KEVE
------------------------- ----- -------- -------- -------- -------- -- --------
4 FILES



:print ldate.cmd
PARM FILES=@, POPT=""

SETVAR XSI_OPT  UPS ( LFT ( "!POPT", 1 ))

IF FINFO ( "LDATELST,TEMP", "EXISTS" ) THEN
    PURGE LDATELST,TEMP
ENDIF
FILE LDATELST;MSG;TEMP;NOCCTL;REC=-40,,F,ASCII;DISC=100000
LISTF !FILES,6;*LDATELST
FILE LDATELST,OLDTEMP
SETVAR XSI_CNT FINFO ( "LDATELST,TEMP", "EOF" )
SETVAR XSI_R   0

IF XSI_OPT = "A" THEN
    ECHO Filename                  Fcode      EOF Created  Modified &
Allocate UL Accessed
ELSE
    ECHO Filename                  Fcode      EOF Created  Modified &
Allocate UL Owner
ENDIF

ECHO ------------------------- ----- -------- -------- -------- &
-------- -- --------
WHILE !XSI_R < !XSI_CNT DO
    INPUT  XSI_FILE < LDATELST
    SETVAR XSI_R         XSI_R + 1
    SETVAR XSI_FILE      RTRIM ( XSI_FILE )

    SETVAR XSI_XD  FINFO ( XSI_FILE, "INTCREATED" )
    SETVAR XSI_XD  "!XSI_XD"
    SETVAR XSI_CD  STR(XSI_XD,5,2)+"/"+STR(XSI_XD,7,2)+"/"+STR(XSI_XD,3,2)

    SETVAR XSI_XD  FINFO ( XSI_FILE, "INTMODDATE" )
    SETVAR XSI_XD  "!XSI_XD"
    SETVAR XSI_MD  STR(XSI_XD,5,2)+"/"+STR(XSI_XD,7,2)+"/"+STR(XSI_XD,3,2)

    SETVAR XSI_XD  FINFO ( XSI_FILE, "INTALLOCDATE" )
    SETVAR XSI_XD  "!XSI_XD"
    SETVAR XSI_RD  STR(XSI_XD,5,2)+"/"+STR(XSI_XD,7,2)+"/"+STR(XSI_XD,3,2)

    SETVAR XSI_XD  FINFO ( XSI_FILE, "INTACCESSED" )
    SETVAR XSI_XD  "!XSI_XD"
    SETVAR XSI_AD  STR(XSI_XD,5,2)+"/"+STR(XSI_XD,7,2)+"/"+STR(XSI_XD,3,2)

    SETVAR XSI_OW  LFT ( FINFO ( XSI_FILE, "OWNER" )+"        ",8)
    SETVAR XSI_FC  LFT ( FINFO ( XSI_FILE, "FMTFCODE" )+"     ",5)
    SETVAR XSI_EF  RHT ( '       ![FINFO ( XSI_FILE, "EOF" )]',8)
    SETVAR XSI_UL  LFT ( '![FINFO ( XSI_FILE, "USER LABELS WRITTEN")]'+' ',2)
    IF XSI_UL = "0 " THEN
       SETVAR XSI_UL "  "
    ENDIF
    SETVAR XSI_FILE   LFT ( XSI_FILE + RPT ( " ", 26 ), 26 )

    IF XSI_OPT = "A"
       ECHO !XSI_FILE!XSI_FC !XSI_EF !XSI_CD !XSI_MD !XSI_RD !XSI_UL !XSI_AD
    ELSE
       ECHO !XSI_FILE!XSI_FC !XSI_EF !XSI_CD !XSI_MD !XSI_RD !XSI_UL !XSI_OW
    ENDIF
ENDWHILE
ECHO ------------------------- ----- -------- -------- -------- &
-------- -- --------
ECHO !XSI_CNT FILES

DELETEVAR XSI_@
PURGE LDATELST,TEMP
:

* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *

ATOM RSS1 RSS2