Debbie, you should be able to accomplish these tasks without
spending a dime. I have developed some command files that will
basicly do the same thing that you are looking for. Here is an
example of them:
USER DEFINED COMMAND FILE: PASSCHG.CMD.SYS
SETVAR PASS_CHECK "!HPUSER.PASS"
SETVAR HPMSGFENCE 2
WHILE NOT FINFO("!PASS_CHECK","EXISTS")
ECHO
ECHO
ECHO --------------------------------------------------------
ECHO - NOTE: YOUR SYSTEM PASSWORD HAS EXPIRED -
ECHO - -
ECHO - PLEASE ENTER YOUR CURRENT PASSWORD AT THE PROMPT -
ECHO - BELOW, THEN ENTER YOUR NEW PASSWORD TWICE FOR -
ECHO - VERIFICATION. YOUR NEW PASSWORD MUST START WITH -
ECHO - A LETTER BUT MAY CONTAIN NUMBERS. MAX LENGTH=8. -
ECHO --------------------------------------------------------
ECHO
ECHO
SETVAR CIERROR 0
CONTINUE
PASSWORD
IF CIERROR = 2503
ECHO
ECHO -----------------------------------------------
ECHO - SPELLING NOT CONSISTANT - PLEASE START OVER -
ECHO -----------------------------------------------
ECHO
ENDIF
IF CIERROR = 2528
ECHO
ECHO ------------------------------------------------------
ECHO - NEW PASSWORD MUST BE DIFFERENT - PLEASE START OVER -
ECHO ------------------------------------------------------
ECHO
ENDIF
IF CIERROR = 762
ECHO
ECHO ------------------------------------------------------
ECHO - MAXIMUM LENGTH IS 8 CHARACTERS - PLEASE START OVER -
ECHO ------------------------------------------------------
ECHO
ENDIF
IF CIERROR = 764
ECHO
ECHO
---------------------------------------------------------------
ECHO - PASSWORD MUST BE LETTERS & NUMBERS ONLY - PLEASE START
OVER -
ECHO
---------------------------------------------------------------
ECHO
ENDIF
IF CIERROR = 1441
ECHO
ECHO
-------------------------------------------------------------
ECHO - ENTER YOUR CURRENT PASSWORD CORRECTLY - PLEASE START OVER
-
ECHO
-------------------------------------------------------------
ECHO
ENDIF
IF CIERROR = 760
ECHO
ECHO
-------------------------------------------------------------
ECHO - NEW PASSWORD MUST START WITH A LETTER - PLEASE START OVER
-
ECHO
-------------------------------------------------------------
ECHO
ENDIF
IF CIERROR = 0
BUILD !HPUSER.PASS;REC=-80,,F,ASCII
ENDIF
ENDWHILE
SETVAR HPMSGFENCE 0
Every night a batch job runs and purges all pass files that are older than
90 days, thus making the user enter a new password.
And the second:
USER DEFINED COMMAND FILE: CHKSES2.CMD.SYS
PURGE FL1,TEMP>$NULL
PURGE FL2,TEMP>$NULL
PURGE FL3,TEMP>$NULL
FILE FL1;REC=-80,,F,ASCII
SHOWJOB JOB=!HPUSER.!HPACCOUNT>*FL1
NEWFILE
ADDLINE T FL1
ADDLINE D ALL EXCLUDING '#S'
ADDLINE D ALL INCLUDING '#S!HPJOBNUM'
ADDLINE KEEP
ADDLINE YES
ADDLINE EXIT
QUAD <*NEWFILE >$NULL
IF FINFO("FL1",19)>0
ECHO
ECHO -------------------------------------------------------
ECHO - -
ECHO - You are allready logged on to the Generic -
ECHO - system, please logoff your other session -
ECHO - first, or if you are still unable -
ECHO - logon to the system, please have your -
ECHO - supervisor call xxx-xxxx for help. -
ECHO - -
ECHO -------------------------------------------------------
ECHO
PAUSE 2
BYE
ENDIF
SETVAR HPAUTOCONT FALSE
PURGE FL1,TEMP>$NULL
PURGE FL2,TEMP>$NULL
PURGE FL3,TEMP>$NULL
PURGE TEXTFILE,TEMP>$NULL
USER DEFINED COMMAND FILE: NEWFILE.CMD.SYS
parm FILENAME="TEXTFILE", RECLEN=80, FILESIZE=10000
comment *********************************************************
comment * Create a new temporary file and file equate NEWFILE to*
comment * point to it. *
comment * *
comment * FILENAME - the filename. Default is TEXTFILE. *
comment * RECLEN - the record length. Default is 80 bytes. *
comment *********************************************************
purge !FILENAME,temp >$null
build !FILENAME;temp;rec=-!RECLEN,,f,ascii;disc=!FILESIZE
setvar NEWFILE_FILENAME "!FILENAME"
file NEWFILE = !FILENAME,oldtemp
USER DEFINED COMMAND FILE: ADDLINE.CMD.SYS
anyparm STRING=*&*&*
comment *********************************************************
comment * Appends a line of text to a file previously created *
comment * with the NEWFILE command. *
comment *********************************************************
if "!STRING" = "*&*&*"
echo >>*NEWFILE
else
echo !STRING >>*NEWFILE
endif
USER DEFINED COMMAND FILE: QUAD.CMD.SYS
parm FILE_NAME=" "
comment *********************************************************
comment * Run the text editor QUAD. And optionally go directly *
comment * into a file. If a file is specified, the filename *
comment * will be stored as the current file. A filename of * *
comment * can be specified to automatically use the current *
comment * file. *
comment * *
comment * FILE_NAME - the filename of the file to edited. Use *
comment * * to specify the current file. *
comment *********************************************************
if "!FILE_NAME" = "*" then
setvar QUAD_FILE CURR_FILE
else
setvar QUAD_FILE "!FILE_NAME"
endif
if QUAD_FILE <> " " then
setvar CURR_FILE QUAD_FILE
run NEWQUAD.UTIL.SYS;parm=1;info="T !QUAD_FILE"
else
run NEWQUAD.UTIL.SYS;parm=1
endif
deletevar QUAD_@
This is assuming you have or have access to QUAD.
-------------------------------------------------------------------------------------------------------------------------------
If you can implement this, you can be a hero too, and save your company
thousands like I do.
It's to bad I don't get any of the cash-o-la that I save my company. Oh
well, back to the drawing
board. P.S. I love cut and paste.
Jeff Sullivan
[log in to unmask]
|
