Gary Pastor wrote:
>
> We have 2 HP3000 computers.
>
> 1. HP3000/939  DTC48 plus 3 serial printers.
>
> 2. HP3000/937 no DTC and no printers.
>
> Is it possible using Samba to print from the 937 to the printers on
> the 939.
>
> Thanks
>
> Gary Pastor

Gary,

Here is a CI script invoking smbclient which is a program
which you can attach to printer or file shares on other
Servers.  The Servers can be Windows NT, Windows 95 or
HP 3000's running the Samba server.

In this script I have both NT Servers and HP 3000 Servers.

Note: The doubling of \\ to \\\\ in the printer references
      in the script is because Posix/Unix interprets it as an
      escape character, so you need two to represent one.

The real key to the script is when I run SH.HPBIN.SYS.
from the colon prompt to get at the Posix smbclient (Samba)
utility to route a file to any of the above printers.

Hope this helps!

:print sambapr.cmdfiles;page=0
COMMENT ********************************************************
COMMENT
COMMENT                    SAMBA PRINT TO
COMMENT               PC NETWORK PRINTERS AND
COMMENT               HP 3000 SPOOLED PRINTERS
COMMENT
COMMENT WHO:
COMMENT        CUSTOMER - ESWR (EVT)         ###-####
COMMENT        CUSTOMER - ESWR (777)         ###-####
COMMENT        CUSTOMER - ESWR (RTN)         ###-####
COMMENT        CUSTOMER - ESWR (PSD)         ###-####
COMMENT        SUPPORT  - ESWR PROGRAMMERS   ###-####
COMMENT
COMMENT WHAT:
COMMENT        SAMBA SMBCLIENT RUN THROUGH CI COMMAND FILE
COMMENT        1) SELECT THE PC NETWORK PRINTER TO PRINT TO.
COMMENT        2) SELECT THE FILE IN THIS FORMAT /ACCOUNT/GROUP/FILENAME
COMMENT
COMMENT WHERE:
COMMENT        SAMBAPR.CMDFILES FOR ESWR FOCAL USE
COMMENT        IE; XEQ SAMBAPR.CMDFILES
COMMENT
COMMENT WHY:
COMMENT        TO SEND HP 3000 PRINT FILES TO PC NETWORK PRINTERS
COMMENT        THAT ARE IN THE COMMAND FILE MENU
COMMENT
COMMENT WHEN:
COMMENT        RUN FROM THE COLON PROMPT ANY TIME
COMMENT        IE; XEQ SAMBAPR.CMDFILES
COMMENT
COMMENT***********************************************************
COMMENT

WHILE(TRUE)

SETVAR PRINTER1   "\\\\NT-RTN-34\\P871216 "
SETVAR LOCATION1  "NT "

SETVAR PRINTER2   "\\\\NT-RTN-34\\P871212 "
SETVAR LOCATION2  "NT "

SETVAR PRINTER3   "\\\\NT-RTN-34\\P871218 "
SETVAR LOCATION3  "NT "

SETVAR PRINTER4   "\\\\EBS.RTN.BOEING.COM\\PRINT"
SETVAR LOCATION4  "NT "

SETVAR PRINTER5   "\\\\NT-EVT-14\\40874d403"
SETVAR LOCATION5  "NT "

SETVAR PRINTER6   "\\\\NT-RTN-40\\P588806  "
SETVAR LOCATION6  "NT "

SETVAR PRINTER7   "\\\\NT-RTN-04\\P871363  "
SETVAR LOCATION7  "NT "

SETVAR PRINTER8   "\\\\NT-RTN-40\\P588787  "
SETVAR LOCATION8  "NT "

SETVAR PRINTER9   "\\\\SITE133\\LP         "
SETVAR LOCATION9  "NT "

SETVAR PRINTER10  "\\\\SITE133\\RLP        "
SETVAR LOCATION10 "HP 3000 "

SETVAR PRINTER11  "\\\\SITE100\\LP         "
SETVAR LOCATION11 "HP 3000  "

SETVAR PRINTER12  "\\\\SITE100\\RLP        "
SETVAR LOCATION12 "HP 3000 "

SETVAR PRINTER13  "\\\\SITE123\\LP         "
SETVAR LOCATION13 "HP 3000 "

SETVAR PRINTER14  "\\\\SITE123\\RLP        "
SETVAR LOCATION14 "HP 3000 "

SETVAR PRINTER15  "\\\\SITE123\\EDC        "
SETVAR LOCATION15 "HP 3000  "


ECHO ![CHR(27)+'H'+CHR(27)+'J'+CHR(13)]
ECHO ![CHR(27)+'&a12c0Y'&
      +CHR(27)+'&dBPRINT TO PC NETWORK PRINTERS AND HP 3000 SPOOLED
PRINTERS'&
      +CHR(27)+'&d@']
ECHO
ECHO    1) SELECT THE PC NETWORK PRINTER TO PRINT TO.
ECHO    2) SELECT THE FILE IN THIS FORMAT /ACCOUNT/GROUP/FILENAME
ECHO
ECHO 1.  !PRINTER1  !LOCATION1
ECHO 2.  !PRINTER2  !LOCATION2
ECHO 3.  !PRINTER3  !LOCATION3
ECHO 4.  !PRINTER4  !LOCATION4
ECHO 5.  !PRINTER5  !LOCATION5
ECHO 6.  !PRINTER6  !LOCATION6
ECHO 7.  !PRINTER7  !LOCATION7
ECHO 8.  !PRINTER8  !LOCATION8
ECHO 9.  !PRINTER9  !LOCATION9
ECHO 10. !PRINTER10  !LOCATION10
ECHO 11. !PRINTER11  !LOCATION11
ECHO 12. !PRINTER12  !LOCATION12
ECHO 13. !PRINTER13  !LOCATION13
ECHO 14. !PRINTER14  !LOCATION14
ECHO 15. !PRINTER15  !LOCATION15

SETVAR I 0

WHILE (!I < 1 OR !I > 15 ) DO
  ECHO
  INPUT NAME=I;PROMPT="ENTER THE PRINTER OPTION NUMBER OR [Q]:"
  IF ( ALPHA('!I') ) THEN
    SETVAR I UPS('!I')
    IF ('!I' = 'Q') THEN
      RETURN
    ENDIF
    ECHO SELECT A NUMBER BETWEEN 1-15
    SETVAR I 0
  ELSEIF ( NUMERIC('!I') ) THEN
    IF ( !I < 1 OR !I > 15) THEN
       ECHO SELECT A NUMBER BETWEEN 1-15
    ENDIF
  ELSE
    ECHO SELECT A NUMBER BETWEEN 1-15
    SETVAR I 0
  ENDIF
ENDWHILE
SETVAR P "![PRINTER!I]"


SETVAR FILE '999'
WHILE(NOT(FINFO('!FILE','EXISTS'))) DO
  ECHO
  INPUT NAME=FILE;PROMPT="ENTER THE FILE TO PRINT OR [Q]:"
  IF ('!FILE' = 'Q' OR '!FILE' = 'q') THEN
    RETURN
  ENDIF
  IF(NOT(FINFO('!FILE','EXISTS'))) THEN
    ECHO SELECT A FULLY QUALIFIED FILE THAT EXISTS ;IE
/ACCOUNT/GROUP/FILENAME
  ENDIF
ENDWHILE

SETVAR F "![FILE]"

CONTINUE
PURGE T,TEMP > $NULL

CONTINUE
PURGE T  > $NULL

ECHO printmode text >>T
ECHO translate      >>T
ECHO print !F       >>T
ECHO EXIT           >>T

SAVE T

RUN SH.HPBIN.SYS;INFO=&
"-L -c '/usr/local/samba/bin/smbclient !P -N -P < T'" > $NULL

ECHO
ECHO ![CHR(27)+'&dBFINISHED...'+CHR(27)+'&d@']

PAUSE 3

CONTINUE
PURGE T > $NULL

ENDWHILE

--
  Joe Whitlock                  | Work Email: [log in to unmask]
  The Boeing Company            | Work MS EXCHANGE:
[log in to unmask]
  P.O. Box 3707                 | Home Email: [log in to unmask]
  MS 6C-LU                      | Tel:      206-234-1478
  Seattle, WA 98124-2207        | Fax:      206-237-7230