>I realize this is probably a simplistic question and I know there are
>products you can buy to accomplish this easily but....
>Using the regular store/restore - could somebody send me an example of a
>command file that would execute an unattended backup at midnight. This
>would have to abort all active sessions. It would be nice to do an
>incremental backup rather than a full backup.
>Thanks for any suggestions
>[log in to unmask]
Hi "[log in to unmask]",
following a tiny command script for aborting all jobs and sessions except
the current one. Feel free to modify but then remove my name from
header, please.
Regards
Holger Wiemann
,,,,,
(o o)
------------------------------------------------------.ooO--(_)--Ooo.------
Hewlett-Packard GmbH
Germany
E-Mail: [log in to unmask],
[log in to unmask]
Desk: Holger Wiemann /HPGRMY/05
______________________________________________________________Oooo._______
.oooO ( )
( ) ) /
\ ( (_/
\_)
.......................................................................
Item Subject: LOGOFF
Filename: LOGOFF
PARM whatjobs=@
COMMENT ***************************************************
COMMENT logoff command file
COMMENT Hewlett Packard, Copyright (c) 1995
COMMENT by Holger Wiemann
COMMENT
COMMENT aborts all jobs/session with 'ABORTJOB'
COMMENT except current job/session
COMMENT you need SM-capability for effective use
COMMENT jobsecurity has to be 'low' on system
COMMENT use at own risc
COMMENT MPE/iX 4.0 and 5.0 tested
COMMENT ***************************************************
TELLOP LOGOFF COMMAND FILE ACTIVATED !!!
COMMENT ***************************************************
COMMENT create temporary file with showjob
COMMENT ***************************************************
CONTINUE
PURGE purglist,TEMP
FILE purglist;rec=-80,,F,ASCII;DISC=2048;MSG;NOCCTL
SHOWJOB JOB=!whatjobs;*purglist
COMMENT ***************************************************
COMMENT create current job/session id
COMMENT ***************************************************
SETVAR currjob,"#!HPJOBTYPE!HPJOBNUM"
COMMENT ***************************************************
COMMENT length of purglist
COMMENT ***************************************************
SETVAR entrycount,FINFO("PURGLIST","EOF")
COMMENT ***************************************************
COMMENT main loop for aborting jobs and sessions
COMMENT ***************************************************
WHILE entrycount > 0 DO
INPUT lineentry < purglist
IF STR(lineentry,1,1) = "#" THEN
SETVAR i,1
WHILE STR(lineentry,i,1) <> " " DO
SETVAR i,(i + 1)
ENDWHILE
SETVAR jobnumber,STR(lineentry,1,i-1)
IF jobnumber <> currjob THEN
IF STR(jobnumber,2,1) = "S" THEN
TELLOP LOGOFF: ABORTING SESSION !jobnumber
ELSE
TELLOP LOGOFF: ABORTING JOB !jobnumber
ENDIF
CONTINUE
ABORTJOB !jobnumber
COMMENT PAUSE 5
ENDIF
ENDIF
SETVAR entrycount, (entrycount - 1)
ENDWHILE
TELLOP LOGOFF: SEARCHING GHOST SESSIONS AND JOBS
PAUSE 60
CONTINUE
PURGE purglist,TEMP
COMMENT ***************************************************
COMMENT create temporary file with showdev
COMMENT ***************************************************
PURGE purglist,TEMP
CONTINUE
FILE purglist;rec=-80,,F,ASCII;DISC=2048;MSG;NOCCTL
SHOWDEV >*purglist
COMMENT ***************************************************
COMMENT length of purglist
COMMENT ***************************************************
SETVAR entrycount,FINFO("PURGLIST","EOF")
COMMENT ***************************************************
COMMENT main loop for finding ghost sessions and jobs
COMMENT ***************************************************
WHILE entrycount > 0 DO
INPUT lineentry < purglist
IF STR(lineentry,25,1) = "#" THEN
SETVAR i,25
WHILE STR(lineentry,i,1) <> ":" DO
SETVAR i,(i + 1)
ENDWHILE
SETVAR jobnumber,STR(lineentry,25,i - 25)
SETVAR ldevnumber,STR(lineentry,1,5)
IF jobnumber <> currjob THEN
IF STR(jobnumber,2,1) = "S" THEN
TELLOP LOGOFF: POSSIBLE GHOST SESSION !jobnumber
TELLOP LOGOFF: ON LDEV !ldevnumber
ELSE
TELLOP LOGOFF: POSSIBLE GHOST JOB !jobnumber
TELLOP LOGOFF: ON LDEV !ldevnumber
ENDIF
ENDIF
ENDIF
SETVAR entrycount, (entrycount - 1)
ENDWHILE
TELLOP LOGOFF COMMAND FILE FINISHED !!!
|
