Subject: | |
From: | |
Reply To: | |
Date: | Tue, 20 May 2003 11:48:12 -0400 |
Content-Type: | text/plain |
Parts/Attachments: |
|
|
Lars Appel wrote:
>> ZZUSEZIP 1B BA 1094 2147483647 1 16 1 *
>
> Just guessing, but given that Telamon's MAIL utility (unlike sendmail)
> has an MPE biased heritage, it might be that it does not like the file
> in bytestream format. Have you tried "/bin/frombyte -b" and then send
> the resulting 256 FB file instead?
Lars is correct. Here's a reusable piece of JCL from one of our jobs.
(The email addresses have been munged for obvious reasons!) You don't
have to do it this way (i.e. copying the original file and using the -m
option with zip), but I like it because if the 'textfile' is left
behind, I know there was a problem.
!# Part 2: ZIP and MAIL the file.
!
!# Setup input, text, zip, and binary file names.
!setvar inpfile "/!!HPACCOUNT/CCSGDATA/ITEMDMD"
!setvar textfile "ItemDemand.txt"
!setvar zipfile "ItemDmd.zip"
!setvar binzip "ItemDemand.zip"
!# Setup email addresses and vars used by MAIL program.
!setvar mailto "[log in to unmask]"
!setvar mailsmtphost "email_server"
!setvar mailfrom "hp![word(hpcpuname,' -',2)]@ourdomain.com"
!setvar mailsubject "!HPACCOUNT - ITEMDMD File"
!
!# Copy the ITEMDMD.CCSGDATA file to ./ItemDemand.txt .
!purge ./!textfile
!copy !inpfile,./!textfile
!
!# Compress the ./ItemDemand.txt file into a .ZIP archive.
!# Options used in Zipping:
!# -j junk (i.e. don't record) the directory names
!# -9 compress better
!# -l convert LF to CR LF
!# -m move into zipfile (i.e. delete original text file)
!purge ./!zipfile
!zip '-j9lm !zipfile !textfile'
!
!# In order for the .ZIP file to be emailed from the 3000 it has
!# to be converted using FROMBYTE with the '-b' (binary) option.
!# This retains all the data and makes it possible for the file to
!# be sent as a binary attachment (without confusing the mailer).
!purge ./!binzip
!frombyte '-b ./!zipfile ./!binzip'
!
!# Mail the .ZIP file to user. Using -z option for a binary attachment.
!mail.pub.telamon "-t !mailto -z ./!binzip=!binzip &
!The attached ZIP file contains the ItemDemand File for Access DBase."
!
!EOJ
HTH,
Patrick
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Patrick Santucci
HP e3000 Systems Administrator
** I want my MPE!!! **
Computer Operations Team Lead
Networking Services Department
Cornerstone Brands, Inc.
http://cornerstonebrands.com
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|
|
|