Barry (I believe it was) presented a posix script to show current sessions
with ipaddr.
Here is an MPE script.
PARM SESID=""
ANYPARM STUFF=""
IF "!SESID" = "" OR "!SESID" = "@" THEN
SHOWJOB JOB=@S >SLST
XEQ !HPFILE ALL <SLST
PURGE SLST,TEMP
ELSEIF "!SESID" = "ALL" THEN
SETJCW JCW=0
ECHO Session Ldev IP User
ECHO ------- ---- --------------- -----------------------------------
WHILE JCW = 0 DO
SETJCW CIERROR=0
SETVAR HPMSGFENCE 2
SETVAR _SSID ""
CONTINUE
INPUT _SSID
SETVAR HPMSGFENCE 0
IF CIERROR <> 0 THEN
SETJCW JCW=1
ELSEIF LFT ( _SSID, 1 ) = "#" THEN
XEQ !HPFILE !_SSID
ENDIF
ENDWHILE
ECHO ------- ---- --------------- -----------------------------------
DELETEVAR _SSID
ELSE
SETVAR _SSDV JINFO ( "!SESID", "LDEVOUT" )
ECHO ![LFT( "!SESID ",7)] &
![LFT ( "!_SSDV ",4)] &
![LFT (JINFO ( "!SESID", "IPADDR" )+" ",15)] &
![LFT (JINFO ( "!SESID", "JOBUSERACCOUNTGROUP" )+RPT(" ",35),35)]
DELETEVAR _SSDV
ENDIF
:SS
Session Ldev IP User
------- ---- --------------- -----------------------------------
#S836 20 CONSOLE,OPERATOR.SYS,OPERATOR
#S869 8 192.168.20.124 SCOTT.MMDEV,SCOTT
#S873 23 192.168.20.124 SCOTT,MANAGER.SYS,PUB
#S899 28 192.168.20.126 KEVEN.PMDEV,KEVEN
#S906 22 127.0.0.1 LISTREV,SCOTT.MMHPSRC,SCOTT
#S907 30 GUI,MGR.SURVIVAL,PUB
------- ---- --------------- -----------------------------------
> This last session, S907, is an RPM session.
> _____________________________________________________________
> Keven Miller mailto:[log in to unmask] http://www.exegesys.com
>
|