John,

If your menu program is flexible enough to allow you to configure something that
would allow the user to specify the PC file name then you should be able to
'pass' that name to a command file, perform the transfer and run the needed
program without having the user drop into MPE (You may have to exit 'block mode'
if the menu uses it).

The attached command file was used in our site to validate user ids during a
Novell server upgrade.   It transfers the specified file to the HP using a
predefined name, submits a batch job to perform the validation (this was done
for security reasons and the job had 'hipri'), waits around until the batch job
is done and then transfers the resulting file back to the PC.

You could place the user specified filename into a CI variable (setvar ufname
"userfile") and then invoke your version of the command file as follows:
     RUN CI.PUB.SYS;PARM=3;INFO="mycmdfl.pub !ufname"


Regards
Paul Christidis
(310) 513-5808

parm  userfile, delay=10
setvar bell chr(7)
echo !bell !bell
setvar pc_host_file "usrlist.PUB.TESTACCT"
setvar pc_infile DWNS("!userfile")
setvar pc_pos POS(".",pc_infile) - 1
if pc_pos < 1 then
   setvar pc_pos LEN(pc_infile)
endif
setvar destfile STR(pc_infile, 1, pc_pos) + ".csv"
showtime
echo
echo     You have invoked a command to transfer a file containing a
echo  list of user ids for validation against a 'locator' file.
echo     A batch process is invoked to perform the actual validation
echo  and upon completion the 'validated' file will be returned to
echo  your PC.  The returned file will be named
echo
echo     The returned file will be named: !destfile
echo
pause !delay
setvar esc chr(27)
purge !pc_host_file > $null
set echo=off
continue
echo !esc&oBSEND !userfile to !pc_host_file ascii delete
input pc_link
continue
!pc_link
input pc_result
set echo=on
###
if pc_result = "S" AND finfo (pc_host_file, "exists") then
  purge vdone.PUB.TESTACCT > $null
  echo
  echo  Received (!pc_infile).  Submitting batch process... !bell
  jstream validate.job.sys > $null
  setvar pc_vloop 0
  while NOT finfo("vdone.PUB.TESTACCT","exists") do
    pause 1
    setvar pc_vloop pc_vloop + 1
  endwhile
  set echo=off
  continue
  echo !esc&oBRECEIVE !destfile from validusr.PUB.TESTACCT ascii delete
  input pc_link
  continue
  !pc_link
  input pc_result
  set echo=on
  echo
  echo  The 'validated' user list file has been returned to your PC
  echo  in the file named: !destfile
  echo
else
  echo
  echo  !bell Error occured.  File was not transfered..
  echo
endif
showtime





Hi All

I would appreciate some ideas here please.
The environment is a 3K with PC's running Reflections
for Windows.
The users prepare files on their PC's and transfer
them to the 3k using relections file transfer. They
then stream a job to process the files. The job
expects the files to be in a special group with a
standard naming convention. There is a menu program
that allows them to drop into MPE for the transfer and
to stream the job.
I hate this.
I want them out of MPE. Also they get the file name
and group wrong and anything can happen.

The menu program is flexible. I can set up an entry
that will run PCLINK2 when the users start file
transfer in relections. Also a menu entry to stream
the job. That keeps them out of MPE, but does not
solve the file name and destination group.

What I would like is:
1) transfer the PC data into a temporary file of a
specific name.
2) run the programs on line to process the temporary
file.

Running the programs on line is no problems, but how
can I control the destination file name and location?

Any suggestions greatfully received.

Thanks
John Edwards


__________________________________________________
Do You Yahoo!?
Talk to your friends online with Yahoo! Messenger.
http://im.yahoo.com