Subject: | |
From: | |
Reply To: | |
Date: | Thu, 27 Apr 2006 12:03:05 -0400 |
Content-Type: | text/plain |
Parts/Attachments: |
|
|
Here is a script I use a lot. It checks for outstanding print jobs on
several devices in one fell swoop (filtering a but according to our local
criteria).
:PRINT PRFILES ;PAGE=0
#
# Edward Berner
# Yosemite Community College District
# 5/28/2003
#
SETJCW INSIDEMPEX 0
IF INSIDEMPEX = 1 THEN
MPE XEQ CI.PUB.SYS;INFO="!HPFILE";PARM=3
RETURN
ENDIF
SETVAR PRFILES_DEVICES "REPORT LP 6 104"
SETVAR PRFILES_DEVICES PRFILES_DEVICES + " ISLASER1 780 DPLASER 105"
SETVAR PRFILES_DEVICES PRFILES_DEVICES + " DPPRT 121 ISLASER2 782"
SETVAR PRFILES_DEVICES PRFILES_DEVICES + " LP2 783"
SETVAR PRFILES_COUNT WORDCNT(PRFILES_DEVICES)
SETVAR PRFILES_INDEX 1
WHILE PRFILES_INDEX <= PRFILES_COUNT
SETVAR PRFILES_DEVICE WORD(PRFILES_DEVICES,,PRFILES_INDEX)
ERRCLEAR
LISTSPF O@;SELEQ=[DEV=!PRFILES_DEVICE &
AND STATE <> SPSAVE AND FILEDES <> $STDLIST &
AND STATE <> CREATE ];DETAIL > $NEWPASS
IF CIERROR = 4809 THEN
ECHO No waiting print files for device !PRFILES_DEVICE
ELSEIF CIERROR = 0 THEN
ECHO ![RPT("-",70)]
ECHO Waiting print files on device !PRFILES_DEVICE
SED.HPBIN.SYS "-n 1,/^INPUT/p" < $OLDPASS > $NEWPASS
SED.HPBIN.SYS "/^INPUT/d" < $OLDPASS
ELSE
ECHO ![RPT("-",70)]
ECHO Unexpected CIERROR (!CIERROR) while listing
ECHO print files for device !PRFILES_DEVICE
PRINT $OLDPASS;PAGE=0
ENDIF
SETVAR PRFILES_INDEX PRFILES_INDEX + 1
ENDWHILE
DELETEVAR PRFILES_@
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|
|
|