Our backup hung list night, saying
"SENDMAIL TO SYSGEN FROM STORE FAILED. (S/R 1741)"
which I don't recall seeing before.
Operator aborted it in the morning and all is well, at least until tonight's
backup (and I will be making some changes before then).
Any ideas on what causes an S/R 1741 ?
Normally here a hung backup job would be killed off after a few hours by a
"killtape" job, which throws abortios and abortjobs at the wall until they
stick. But a while back I (foolishly?) added a command file to beginning of
that job to show a lot of tape-drive-related info, in the hope that it would
help me diagnose what had gone wrong with the backup.
However, that command file also hung, so the killtape job never go around to
trying to abort anything.
I'm including it below, in case anyone wants to suggest improvements, or
even use it when their tape drive is not so messed-up -- it normally works
fine, I swear. I can be helpful to run it in the afternoon to make sure the
night's tape has been mounted ok. For that matter, the backup job itself
calls it before it starts the backup, so I know the tape drive looked ok
last night at the start of the backup job.
Im pretty sure it hung evaluating one of the following...
devinfo(7, "TAPEONLINE")
devinfo (7, "IntTapeError")
devinfo (7, "TapeTrackError")
devinfo (7, "BOT")
...meaning that one of those devinfo calls can be toxic if your tape is hung
for the wrong reason.
But first it successfully got thru all the following:
devinfo (7, "Available")
devinfo (7, "TapeWriteProtect")
devinfo (7, "Ownership")
![devinfo (7, "OwnerJobNum")]
![devinfo (7, "OwnerPin")]
![pinfo (devinfo (7, "OwnerPin"),"ProgramName")]
The end of the killtape job-listing looks like:
:XEQ CHKTAPE.SYSCMD.SHR 7, more, check ldev 7 status
*Warning* Ldev 7 is owned
- Owner job# = #J6405
FASTBACK,MANAGER.SYS
- Owner pin# = 492
JSMAIN.PUB.SYS
JOB aborted by system management. (CIERR 6027)
CPU sec. = 1. elapsed min. = 464. FRI, MAY 1, 2009, 9:31 AM
The command-file is:
:print chktape.syscmd.shr;page=0
option NOLIST
parm _ignored = 7
parm _xtra = ""
anyparm _COMMENT = ""
setvar TAPE_ERRORS 0
if not devinfo (7, "Available")
echo *Warning* Ldev 7 status is not "available" ![chr(7)]
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if devinfo (7, "TapeWriteProtect")
echo *Warning* Tape in Ldev 7 is write-protected ![chr(7)]
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if devinfo (7, "Ownership") <> ""
echo *Warning* Ldev 7 is owned
echo - Owner job# = ![devinfo (7, "OwnerJobNum")]
setvar CHKTAPE_JOBNUM devinfo (7, "OwnerJobNum") - chr(0)
echo ![jinfo (CHKTAPE_JOBNUM,"JobUserAccount")]
echo - Owner pin# = ![devinfo (7, "OwnerPin")]
echo ![pinfo (devinfo (7, "OwnerPin"),"ProgramName")]
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if not devinfo(7, "TAPEONLINE")
echo *Warning* Ldev 7 is not on-line ! ![chr(7)]
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if devinfo (7, "IntTapeError") <> 0
echo *Warning* Ldev 7 has error# ![devinfo (7, "IntTapeError")]
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if devinfo (7, "TapeTrackError")
echo *Warning* Ldev 7 shows a tape track error
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if not devinfo (7, "BOT")
echo *Warning* Ldev 7 is not at beginning-of-tape
setvar TAPE_ERRORS TAPE_ERRORS + 1
endif
if TAPE_ERRORS = 0
echo Tape drive (ldev 7) looks OK for a backup.
ELSE
echo Backup probably won't work if this isn't fixed ![chr(7)]
echo If you just put a tape in the drive, wait a minute,
echo then try "XEQ !HPFILE"
if "!_xtra" = ""
echo or "xeq !hpfile,anything" for some extra info
endif
endif
if "!_xtra" <> ""
echo Tape-related info as reported by "devinfo"
echo Tape Avail (Up) = ![devinfo (7, "Available")]
echo Tape On-line = ![DEVINFO (7, "TapeOnLine")]
echo Write Protect = ![devinfo (7, "TapeWriteProtect")]
echo Tape Density = ![devinfo (7, "TapeDensity")]
echo Ownership = ![DEVINFO (7, "Ownership")]
if DEVINFO (7, "Ownership") <> ""
echo Owner Job# = ![DEVINFO (7, "OwnerJobNum")]
endif
echo Owner PIN# = ![DEVINFO (7, "OwnerPin")]
echo Tape Error# = ![DEVINFO (7, "IntTapeError")]
echo Tape Error = ![DEVINFO (7, "TapeError")]
echo Track Error = ![DEVINFO (7, "TapeTrackError")]
echo Begining of tape = ![DEVINFO (7, "BOT")]
echo End of Tape = ![DEVINFO (7, "TapeEOF")]
endif
return
# CHKTAPE.SYSCMD.SHR Dave Powell, MMfab 01/31/2008
#
# Use to check if ldev 7 has a tape and is ok for a backup
#
# Parms:
# 1 - ignored, might later become ldev# to check
# 2 - input anything to make it display some extra info
# 3 - ignored "anyparm" so jobs & cmd-files can comment
# what they are doing when they call this.
#
#
# ---------------------------------------------------------
# 01/31/2008 tests with NO tape in the drive
# Tape Density = 2
# Tape Error = NON-FATAL
# Track Error = FALSE
# Tape On-line = FALSE <--- this is the best item of the bunch
# Owner PIN# = 0
# Ownership =
# Owner Job# = #S667 <--- incorrect = caller's session#
# Tape Error# = 0
# Begining of tape = TRUE
#
# ---------------------------------------
# Devinfo oddities:
#
# "Owner's job# incorrectly shows caller's job# when the
# drive is idle, whether there is a tape in it or not.
#
# Owner's job# has an extra null char in the middle, after
# the "#S" and before the numeric part.
# So
# echo ![jinfo (devinfo (7, "OwnerJobNum") - chr(0),"JobName")]
# works, but
# echo ![jinfo (devinfo (7, "OwnerJobNum"),"JobUserAccount")]
# fails.
#
# "BOT", beginning of tape, is true even when a store is
# in progess.
* To join/leave the list, search archives, change list settings, *
* etc., please visit http://raven.utc.edu/archives/hp3000-l.html *
|
