>>We are now comming to the "fun" part of our Y2K project and have started
to
look at all of the Quiz reports that people have wrapped around MM/3000.

Does anyone have a routine that they are using with QUIZ to handle the
MM/3000
date format that they would be willing to share?
>>

Here is some quiz code that I used for PM/3000.
Same deal with the dates.  DATE-OUT is the PM/3000
date with the "A" format.  Note; that since we
were not going to be using PM3000 after about 1995,
I only coded this to handle up to 2019.
Also note that the "pivot date" logic used was
for 90 and up being 1990 and anything else being
2000 and up.  You could pick any date as the
pivot date.
Also note this logic is being used in Quiz 7.29C8.
Version 8.19 is supposed to be able to handle these
dates with the "A".  But we decided to go ahead
and make these changes rather than wait for that
version to be released before starting.

= = =
DEFINE END-DATE DATE CENTURY EXCLUDED = PARM PROMPT &
    "ENTER ENDING DATE FOR THIS REPORT (YYMMDD): "
 DEFINE BEGIN-DATE DATE CENTURY EXCLUDED = PARM PROMPT &
    "ENTER BEGIN DATE FOR THIS REPORT (YYMMDD): "
 DEFINE DATE-OUT-X CHAR*6 = "0" + DATE-OUT [2:5] &
     IF DATE-OUT [1:1] EQ "A"                    &
   ELSE "1" + DATE-OUT [2:5]                     &
     IF DATE-OUT [1:1] EQ "B"                    &
   ELSE DATE-OUT
 DEFINE DATE-OUT-YMD DATE CENTURY EXCLUDED = NCONVERT (DATE-OUT-X)
 DEFINE DATE-OUT-CC  DATE CENTURY INCLUDED = &
        ADDCENTURY (DATE-OUT-YMD,19)         &
     IF DATE-OUT-X [1:1] EQ "9"              &
   ELSE ADDCENTURY (DATE-OUT-YMD,20)
 DEFINE END-DATE-X     CHAR*6 = ASCII (END-DATE,6)
 DEFINE END-DATE-CC DATE CENTURY INCLUDED = &
        ADDCENTURY (END-DATE,19)            &
     IF END-DATE-X [1:1] EQ "9"             &
   ELSE ADDCENTURY (END-DATE,20)
 DEFINE BEGIN-DATE-X       CHAR*6 = ASCII (BEGIN-DATE,6)
 DEFINE BEGIN-DATE-CC DATE CENTURY INCLUDED = &
        ADDCENTURY (BEGIN-DATE,19)            &
     IF BEGIN-DATE-X [1:1] EQ "9"             &
   ELSE ADDCENTURY (BEGIN-DATE,20)
 SELECT IF                            &
     DATE-OUT-CC LE END-DATE-CC   AND &
     DATE-OUT-CC GE BEGIN-DATE-CC

= = = =

Paul Christensen
PC Enterprises Inc.
Osakis MN




_______________________________________________________
Get your free, private email at http://mail.excite.com/